mirror of
https://gitlab.gnome.org/GNOME/gimp.git
synced 2025-07-07 19:29:38 +00:00
cfeedb8736
- Use a relative path for GIMP_LOGO_PATH inside the gi-docgen generated HTML, and not an absolute path taken from build dir (otherwise this would break, for installed docs, but also for the tarball and the developer website!). - Also use either gimp-logo.png or gimp-devel-logo.png depending on whether we are on a stable or unstable branch. - Install these in images/ inside the GIMP docs folder, which corresponds to the relative path given to GIMP_LOGO_PATH. - The installed root dir will be $datadir/doc/gimp-2.99/, e.g. /usr/share/doc/gimp-2.99/ - Inside this folder, the library references will be in libgimp-3.0/ and libgimpui-3.0/ (instead of weird Gimp-3.0/ and GimpUi-3.0/). Note that the root dir uses the application version (2.99) whereas the library folder use the API versions. These are different in development phase. - Archive the gi-docgen installed files, not taken from the build dir, to avoid packaging temp files, such as the .toml files. Note that `g-ir-docs` files are still taken from the build dir, as we don't install them yet. - Finally package all this in a directory before archiving in a tar.xz, named the same as the directory (e.g. gimp-api-docs-2.99.13/ inside gimp-api-docs-2.99.13.tar.xz).
38 lines
1,000 B
Meson
38 lines
1,000 B
Meson
# Extra markdown files
|
|
gimp_ui_doc_content_files = [
|
|
'widget-gallery.md',
|
|
]
|
|
|
|
gimp_ui_doc_toml = configure_file(
|
|
input: 'gimp-ui-3.0.toml.in',
|
|
output: '@BASENAME@',
|
|
configuration: {
|
|
'GIMP_VERSION': gimp_version,
|
|
'GIMP_LOGO': '../images/' + (stable ? 'gimp-logo.png' : 'gimp-devel-logo.png'),
|
|
},
|
|
)
|
|
|
|
gimp_ui_docs = custom_target('gimp-ui-docs',
|
|
input: libgimpui_gir[0],
|
|
output: 'libgimpui-@0@'.format(gimp_api_version),
|
|
command: [
|
|
gi_docgen,
|
|
'generate',
|
|
'--quiet',
|
|
'--fatal-warnings',
|
|
'--config', gimp_ui_doc_toml,
|
|
'--output-dir=@OUTPUT@',
|
|
'--no-namespace-dir',
|
|
'--content-dir=@0@'.format(meson.current_source_dir()),
|
|
'--add-include-path=@0@'.format(meson.project_build_root() / 'libgimp'),
|
|
'@INPUT@',
|
|
],
|
|
depends: libgimp_gir[0],
|
|
depend_files: [
|
|
gimp_ui_doc_toml,
|
|
gimp_ui_doc_content_files,
|
|
],
|
|
build_by_default: true,
|
|
install: true,
|
|
install_dir: get_option('datadir') / 'doc' / 'gimp-@0@'.format(gimp_app_version),
|
|
)
|