67d3ffe498
* cedet/srecode/compile.el: * cedet/semantic/mru-bookmark.el: * cedet/semantic/debug.el: * cedet/semantic/complete.el: * cedet/semantic/analyze.el: Require CL when compiling. * cedet/semantic/scope.el (semantic-analyze-scoped-inherited-tag-map): Wrap calculation of tmpscope so that the regular scope will continue to work. * cedet/semantic/idle.el (semantic-idle-tag-highlight): Use semantic-idle-summary-highlight-face as the highlighting. * emacs-lisp/eieio-base.el (eieio-persistent-save): If buffer contains multibyte characters, choose first applicable coding system automatically. * cedet/ede/project-am.el (project-run-target): New method. (project-run-target): New method. * cedet/ede.el (ede-target): Add run target menu item. (ede-project, ede-minor-keymap): Add ede-run-target binding. (ede-run-target): New function. (ede-target::project-run-target): New method. * cedet/ede/proj.el (project-run-target): New method. * cedet/ede/proj-shared.el (ede-gcc-libtool-shared-compiler) (ede-g++-libtool-shared-compiler): Remove SHELL. Remove COMMANDS. Add :rules. (ede-proj-target-makefile-shared-object): Only libtool compilers now available. Add linkers for libtool. (ede-cc-linker-libtool, ede-g++-linker-libtool): New. (ede-proj-makefile-target-name): Always use .la extension. * cedet/ede/proj-prog.el (project-run-target): New method. * cedet/ede/proj-obj.el (ede-cc-linker): Rename from ede-gcc-linker. (ede-g++-linker): Change Change link lines. * cedet/ede/pmake.el (ede-pmake-insert-variable-shared): When searching for old variables, go to the end of the buffer and search backward from there. (ede-proj-makefile-automake-insert-subdirs) (ede-proj-makefile-automake-insert-extradist): New methods. (ede-proj-makefile-create): Use them. * cedet/ede/pconf.el (ede-proj-configure-test-required-file): Force FILE to expand to the current target. Use file-exists-p to check that it exists. * cedet/ede/linux.el (ede-linux-version): Don't call "head". (ede-linux-load): Wrap dir in file-name-as-directory. Set :version slot. * cedet/ede/files.el (ede-get-locator-object): When enabling locate, do so on "top". * cedet/ede/emacs.el (ede-emacs-file-existing): Wrap "dir" in file-name-as-directory during compare. (ede-emacs-version): Return Emacs/XEmacs differentiator. Get version number from different places. Don't call egrep. (ede-emacs-load): Set :version slot. Call file-name-as-directory to set the directory. * cedet/ede/shell.el: New file. * cedet/inversion.el (inversion-decoders): Allow for stray . in alpha/beta variants.
137 lines
4.4 KiB
EmacsLisp
137 lines
4.4 KiB
EmacsLisp
;;; ede-proj-prog.el --- EDE Generic Project program support
|
|
|
|
;; Copyright (C) 1998, 1999, 2000, 2001, 2005, 2008, 2009
|
|
;; Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric M. Ludlam <zappo@gnu.org>
|
|
;; Keywords: project, make
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
;;
|
|
;; Handle building programs from object files in and EDE Project file.
|
|
|
|
(eval-when-compile (require 'cl))
|
|
(require 'ede/pmake)
|
|
(require 'ede/proj-obj)
|
|
|
|
(declare-function ede-shell-run-something "ede/shell")
|
|
|
|
;;; Code:
|
|
(defclass ede-proj-target-makefile-program
|
|
(ede-proj-target-makefile-objectcode)
|
|
((ldlibs :initarg :ldlibs
|
|
:initform nil
|
|
:type list
|
|
:custom (repeat (string :tag "Library"))
|
|
:documentation
|
|
"Libraries, such as \"m\" or \"Xt\" which this program depends on.
|
|
The linker flag \"-l\" is automatically prepended. Do not include a \"lib\"
|
|
prefix, or a \".so\" suffix.
|
|
|
|
Note: Currently only used for Automake projects."
|
|
)
|
|
(ldflags :initarg :ldflags
|
|
:initform nil
|
|
:type list
|
|
:custom (repeat (string :tag "Link Flag"))
|
|
:documentation
|
|
"Additional flags to add when linking this target.
|
|
Use ldlibs to add addition libraries. Use this to specify specific
|
|
options to the linker.
|
|
|
|
Note: Not currently used. This bug needs to be fixed.")
|
|
)
|
|
"This target is an executable program.")
|
|
|
|
(defmethod ede-proj-makefile-insert-automake-pre-variables
|
|
((this ede-proj-target-makefile-program))
|
|
"Insert bin_PROGRAMS variables needed by target THIS."
|
|
(ede-pmake-insert-variable-shared "bin_PROGRAMS"
|
|
(insert (ede-name this)))
|
|
(call-next-method))
|
|
|
|
(defmethod ede-proj-makefile-insert-automake-post-variables
|
|
((this ede-proj-target-makefile-program))
|
|
"Insert bin_PROGRAMS variables needed by target THIS."
|
|
(ede-pmake-insert-variable-shared
|
|
(concat (ede-name this) "_LDADD")
|
|
(mapc (lambda (c) (insert " -l" c)) (oref this ldlibs)))
|
|
;; For other targets THIS depends on
|
|
;;
|
|
;; NOTE: FIX THIS
|
|
;;
|
|
;;(ede-pmake-insert-variable-shared
|
|
;; (concat (ede-name this) "_DEPENDENCIES")
|
|
;; (mapcar (lambda (d) (insert d)) (oref this FOOOOOOOO)))
|
|
(call-next-method))
|
|
|
|
(defmethod ede-proj-makefile-insert-rules ((this ede-proj-target-makefile-program))
|
|
"Insert rules needed by THIS target."
|
|
(let ((ede-proj-compiler-object-linkflags
|
|
(mapconcat 'identity (oref this ldflags) " ")))
|
|
(with-slots (ldlibs) this
|
|
(if ldlibs
|
|
(setq ede-proj-compiler-object-linkflags
|
|
(concat ede-proj-compiler-object-linkflags
|
|
" -l"
|
|
(mapconcat 'identity ldlibs " -l")))))
|
|
(call-next-method)))
|
|
|
|
(defmethod project-debug-target ((obj ede-proj-target-makefile-program))
|
|
"Debug a program target OBJ."
|
|
(let ((tb (get-buffer-create " *padt*"))
|
|
(dd (if (not (string= (oref obj path) ""))
|
|
(oref obj path)
|
|
default-directory))
|
|
(cmd nil))
|
|
(unwind-protect
|
|
(progn
|
|
(set-buffer tb)
|
|
(setq default-directory dd)
|
|
(setq cmd (read-from-minibuffer
|
|
"Run (like this): "
|
|
(concat (symbol-name ede-debug-program-function)
|
|
" " (ede-target-name obj))))
|
|
(funcall ede-debug-program-function cmd))
|
|
(kill-buffer tb))))
|
|
|
|
(defmethod project-run-target ((obj ede-proj-target-makefile-program) &optional command)
|
|
"Run a program target OBJ.
|
|
Optional COMMAND is the command to run in place of asking the user."
|
|
(require 'ede/shell)
|
|
(let ((tb (get-buffer-create " *padt*"))
|
|
(dd (if (not (string= (oref obj path) ""))
|
|
(oref obj path)
|
|
default-directory))
|
|
(cmd nil))
|
|
(unwind-protect
|
|
(progn
|
|
(set-buffer tb)
|
|
(setq default-directory dd)
|
|
(setq cmd (or command
|
|
(read-from-minibuffer
|
|
"Run (like this): "
|
|
(concat "./" (ede-target-name obj)))))
|
|
(ede-shell-run-something obj cmd)
|
|
)
|
|
(kill-buffer tb))))
|
|
|
|
(provide 'ede/proj-prog)
|
|
|
|
;; arch-tag: 0bfa9364-f385-4745-a846-462146a79a25
|
|
;;; ede/proj-prog.el ends here
|