f8dbefbaa5
* lisp/speedbar.el: Use lexical-binding. (speedbar-with-writable): Use `declare`. * lisp/subr.el (def-edebug-spec): Use `declare`. * lisp/cedet/ede/base.el: Use lexical-binding. (ede-with-projectfile): Use `declare`. (recentf-exclude): Declare var. * lisp/cedet/ede/pmake.el: Use lexical-binding. (ede-pmake-insert-variable-shared, ede-pmake-insert-variable-once): Use `declare`. * lisp/cedet/ede/proj-comp.el: Use lexical-binding. (ede-compiler-begin-unique, ede-compiler-only-once) (ede-linker-begin-unique, ede-linker-only-once): Use `declare`. * lisp/cedet/semantic/ctxt.el: Use lexical-binding. (semantic-with-buffer-narrowed-to-context) (semantic-with-buffer-narrowed-to-command): Use `declare`. (semantic--progress-reporter): Declare var. (semantic-ctxt-end-of-symbol-default): Remove unused var `fieldsep`. * lisp/cedet/semantic/lex-spp.el: Use lexical-binding. (define-lex-spp-macro-declaration-analyzer) (define-lex-spp-include-analyzer, semantic-lex-with-macro-used) (define-lex-spp-macro-undeclaration-analyzer): Use `declare`. (semantic-lex-spp-symbol-remove): Rename arg to avoid colliding with dynamic variable `obarray`. (semantic-lex-spp-symbol-pop): Remove unused var `oldvalue`. (semantic-lex-spp-lex-text-string): Remove unused var `analyzer`. * lisp/cedet/semantic/lex.el (define-lex) (semantic-lex-unterminated-syntax-protection, define-lex-analyzer) (define-lex-regex-analyzer, define-lex-block-analyzer) (semantic-lex-catch-errors): Use `declare`. * lisp/cedet/semantic/tag.el: Use lexical-binding. (semantic-with-buffer-narrowed-to-current-tag) (semantic-with-buffer-narrowed-to-tag): Use `declare`. * lisp/cedet/semantic/wisent.el: Use lexical-binding. (define-wisent-lexer): Use `declare`. * lisp/emacs-lisp/cl-lib.el (cl-pushnew): The arg to :test can be any form not just function form. * lisp/org/ob-comint.el (org-babel-comint-in-buffer) (org-babel-comint-with-output): Use `declare`. * lisp/org/ob-core.el (org-babel-map-src-blocks): Use `declare`. (org-babel-result-cond): Simplify edebug spec. * lisp/org/org-clock.el (org-with-clock-position, org-with-clock): * lisp/org/org-agenda.el (org-agenda-with-point-at-orig-entry): * lisp/org/ob-tangle.el (org-babel-with-temp-filebuffer): Use `declare`. * lisp/textmodes/rst.el (push): Remove redundant edebug spec. * lisp/vc/pcvs-parse.el: Use lexical-binding. (cvs-parse-buffer): Rename arg to avoid dynbound conflict. (cvs-or): Use `declare`.
119 lines
3.8 KiB
EmacsLisp
119 lines
3.8 KiB
EmacsLisp
;;; pcmpl-linux.el --- functions for dealing with GNU/Linux completions -*- lexical-binding: t -*-
|
|
|
|
;; Copyright (C) 1999-2021 Free Software Foundation, Inc.
|
|
|
|
;; Package: pcomplete
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; These functions are for use with GNU/Linux. Since they depend on a
|
|
;; certain knowledge of the layout of such systems, they probably
|
|
;; won't work very well on other operating systems.
|
|
|
|
;;; Code:
|
|
|
|
(provide 'pcmpl-linux)
|
|
|
|
(require 'pcomplete)
|
|
|
|
;; Unused.
|
|
;;; (defgroup pcmpl-linux nil
|
|
;;; "Functions for dealing with GNU/Linux completions."
|
|
;;; :group 'pcomplete)
|
|
|
|
;; Functions:
|
|
|
|
;;;###autoload
|
|
(defun pcomplete/kill ()
|
|
"Completion for GNU/Linux `kill', using /proc filesystem."
|
|
(if (pcomplete-match "^-\\(.*\\)" 0)
|
|
(pcomplete-here
|
|
(pcomplete-uniquify-list
|
|
(split-string
|
|
(pcomplete-process-result "kill" "-l")))
|
|
(pcomplete-match-string 1 0)))
|
|
(while (pcomplete-here
|
|
(if (file-directory-p "/proc")
|
|
(directory-files "/proc" nil "\\`[0-9]+\\'"))
|
|
nil #'identity)))
|
|
|
|
;;;###autoload
|
|
(defun pcomplete/umount ()
|
|
"Completion for GNU/Linux `umount'."
|
|
(pcomplete-opt "hVafrnvt(pcmpl-linux-fs-types)")
|
|
(while (pcomplete-here (pcmpl-linux-mounted-directories)
|
|
nil #'identity)))
|
|
|
|
;;;###autoload
|
|
(defun pcomplete/mount ()
|
|
"Completion for GNU/Linux `mount'."
|
|
(pcomplete-opt "hVanfFrsvwt(pcmpl-linux-fs-types)o?L?U?")
|
|
(while (pcomplete-here (pcomplete-entries) nil #'identity)))
|
|
|
|
(defconst pcmpl-linux-fs-modules-path-format "/lib/modules/%s/kernel/fs/")
|
|
|
|
(defun pcmpl-linux-fs-types ()
|
|
"Return a list of available fs modules on GNU/Linux systems."
|
|
(let ((kernel-ver (pcomplete-process-result "uname" "-r")))
|
|
(directory-files
|
|
(format pcmpl-linux-fs-modules-path-format kernel-ver))))
|
|
|
|
(defconst pcmpl-linux-mtab-file "/etc/mtab")
|
|
|
|
(defun pcmpl-linux-mounted-directories ()
|
|
"Return a list of mounted directory names."
|
|
(let (points)
|
|
(when (file-readable-p pcmpl-linux-mtab-file)
|
|
(with-temp-buffer
|
|
(insert-file-contents-literally pcmpl-linux-mtab-file)
|
|
(while (not (eobp))
|
|
(let* ((line (buffer-substring (point) (line-end-position)))
|
|
(args (split-string line " ")))
|
|
(setq points (cons (nth 1 args) points)))
|
|
(forward-line)))
|
|
(pcomplete-uniquify-list points))))
|
|
|
|
(defun pcomplete-pare-list (l r)
|
|
"Destructively remove from list L all elements matching any in list R.
|
|
Test is done using `equal'."
|
|
(while (and l (and r (member (car l) r)))
|
|
(setq l (cdr l)))
|
|
(let ((m l))
|
|
(while m
|
|
(while (and (cdr m)
|
|
(and r (member (cadr m) r)))
|
|
(setcdr m (cddr m)))
|
|
(setq m (cdr m))))
|
|
l)
|
|
|
|
(defun pcmpl-linux-mountable-directories ()
|
|
"Return a list of mountable directory names."
|
|
(let (points)
|
|
(when (file-readable-p "/etc/fstab")
|
|
(with-temp-buffer
|
|
(insert-file-contents-literally "/etc/fstab")
|
|
(while (not (eobp))
|
|
(let* ((line (buffer-substring (point) (line-end-position)))
|
|
(args (split-string line "\\s-+")))
|
|
(setq points (cons (nth 1 args) points)))
|
|
(forward-line)))
|
|
(pcomplete-pare-list
|
|
(pcomplete-uniquify-list points)
|
|
(cons "swap" (pcmpl-linux-mounted-directories))))))
|
|
|
|
;;; pcmpl-linux.el ends here
|