05297e40c0
* lisp/align.el (align): * lisp/bindings.el (undo-repeat-map): * lisp/calc/calc-embed.el (calc-do-embedded): * lisp/calc/calc-prog.el (calc-user-define-invocation): * lisp/calc/calc-yank.el (calc--edit-mode): * lisp/comint.el (comint-history-isearch) * lisp/dired.el (dired-mode): * lisp/emulation/viper.el (viper-mode): * lisp/erc/erc-button.el (erc-button-face): * lisp/erc/erc-track.el (erc-track-enable-keybindings): * lisp/gnus/gnus-art.el (gnus-article-button-face): * lisp/gnus/gnus-eform.el (gnus-edit-form): * lisp/gnus/gnus-sum.el (gnus-summary-stop-at-end-of-message) (gnus-summary-goto-unread): * lisp/icomplete.el (icomplete-show-matches-on-no-input): * lisp/image-mode.el (image-scroll-up): * lisp/international/iso-transl.el (iso-transl-set-language): * lisp/isearch.el (isearch-forward-regexp): * lisp/misc.el (butterfly): * lisp/outline.el (outline-minor-mode-cycle-filter) (outline-minor-mode-cycle): * lisp/progmodes/grep.el (rgrep): * lisp/progmodes/gud.el (gud-gdb-repeat-map, gud-sdb-repeat-map) (gud-dbx-repeat-map, gud-xdb-repeat-map, gud-perldb-repeat-map) (gud-pdb-repeat-map, gud-guiler-repeat-map, gud-jdb-repeat-map): * lisp/progmodes/idlw-shell.el (idlwave-shell-graphics-window-size) (idlwave-shell-mode): * lisp/progmodes/idlwave.el (idlwave-shell-debug-modifiers) (idlwave-list-shell-load-path-shadows): * lisp/progmodes/python.el (python-shell-get-process-or-error): * lisp/repeat.el (repeat-check-key): * lisp/replace.el (query-replace, query-replace-regexp) (read-regexp): * lisp/simple.el (read-extended-command-predicate): * lisp/tab-bar.el (tab-bar-switch-repeat-map) (tab-bar-move-repeat-map): * lisp/term.el (ansi-term): * lisp/textmodes/reftex-index.el (reftex-index-phrases-set-macro-key): * lisp/vc/emerge.el (emerge-scroll-left, emerge-scroll-right): * lisp/windmove.el: * lisp/winner.el (winner-mode): Quote literal keys to get 'help-key-binding' face. * lisp/comint.el (comint-insert-previous-argument): Use regular quotes.
122 lines
3.6 KiB
EmacsLisp
122 lines
3.6 KiB
EmacsLisp
;;; gnus-eform.el --- a mode for editing forms for Gnus -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 1996-2022 Free Software Foundation, Inc.
|
|
|
|
;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
|
|
;; Keywords: news
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; Code:
|
|
|
|
(require 'gnus)
|
|
(require 'gnus-win)
|
|
|
|
;;;
|
|
;;; Editing forms
|
|
;;;
|
|
|
|
(defgroup gnus-edit-form nil
|
|
"A mode for editing forms."
|
|
:group 'gnus)
|
|
|
|
(defcustom gnus-edit-form-mode-hook nil
|
|
"Hook run in `gnus-edit-form-mode' buffers."
|
|
:type 'hook)
|
|
|
|
(defcustom gnus-edit-form-menu-hook nil
|
|
"Hook run when creating menus in `gnus-edit-form-mode' buffers."
|
|
:type 'hook)
|
|
|
|
;;; Internal variables
|
|
|
|
(defvar gnus-edit-form-buffer "*Gnus edit form*")
|
|
(defvar gnus-edit-form-done-function nil)
|
|
|
|
(defvar-keymap gnus-edit-form-mode-map
|
|
:parent emacs-lisp-mode-map
|
|
"C-c C-c" #'gnus-edit-form-done
|
|
"C-c C-k" #'gnus-edit-form-exit)
|
|
|
|
(defun gnus-edit-form-make-menu-bar ()
|
|
(unless (boundp 'gnus-edit-form-menu)
|
|
(easy-menu-define
|
|
gnus-edit-form-menu gnus-edit-form-mode-map ""
|
|
'("Edit Form"
|
|
["Exit and save changes" gnus-edit-form-done t]
|
|
["Exit" gnus-edit-form-exit t]))
|
|
(gnus-run-hooks 'gnus-edit-form-menu-hook)))
|
|
|
|
(define-derived-mode gnus-edit-form-mode lisp-data-mode "Edit Form"
|
|
"Major mode for editing forms.
|
|
It is a slightly enhanced `lisp-data-mode'.
|
|
|
|
\\{gnus-edit-form-mode-map}"
|
|
(when (gnus-visual-p 'group-menu 'menu)
|
|
(gnus-edit-form-make-menu-bar))
|
|
(make-local-variable 'gnus-edit-form-done-function)
|
|
(make-local-variable 'gnus-prev-winconf))
|
|
|
|
(defun gnus-edit-form (form documentation exit-func &optional layout)
|
|
"Edit FORM in a new buffer.
|
|
Call EXIT-FUNC on exit. Display DOCUMENTATION in the beginning
|
|
of the buffer.
|
|
The optional LAYOUT overrides the `edit-form' window layout."
|
|
(let ((winconf (current-window-configuration)))
|
|
(set-buffer (gnus-get-buffer-create gnus-edit-form-buffer))
|
|
(gnus-configure-windows (or layout 'edit-form))
|
|
(gnus-edit-form-mode)
|
|
(setq gnus-prev-winconf winconf)
|
|
(setq gnus-edit-form-done-function exit-func)
|
|
(erase-buffer)
|
|
(insert documentation)
|
|
(unless (bolp)
|
|
(insert "\n"))
|
|
(goto-char (point-min))
|
|
(while (not (eobp))
|
|
(insert ";;; ")
|
|
(forward-line 1))
|
|
(insert (substitute-command-keys
|
|
";; Type \\`C-c C-c' after you've finished editing.\n"))
|
|
(insert "\n")
|
|
(let ((p (point)))
|
|
(gnus-pp form)
|
|
(insert "\n")
|
|
(goto-char p))))
|
|
|
|
(defun gnus-edit-form-done ()
|
|
"Update changes and kill the current buffer."
|
|
(interactive nil gnus-edit-form-mode)
|
|
(goto-char (point-min))
|
|
(let ((form (condition-case nil
|
|
(read (current-buffer))
|
|
(end-of-file nil)))
|
|
(func gnus-edit-form-done-function))
|
|
(gnus-edit-form-exit)
|
|
(funcall func form)))
|
|
|
|
(defun gnus-edit-form-exit ()
|
|
"Kill the current buffer."
|
|
(interactive nil gnus-edit-form-mode)
|
|
(let ((winconf gnus-prev-winconf))
|
|
(kill-buffer (current-buffer))
|
|
(set-window-configuration winconf)))
|
|
|
|
(provide 'gnus-eform)
|
|
|
|
;;; gnus-eform.el ends here
|