f342b7c969
Includes the following pervasive changes: - Move some defvars earlier in the file so they cover earlier let-bindings - Change dynamically scoped `calc-FOO` or `math-FOO` function arguments to just FOO and then let-bind the `calc-FOO` or `math-FOO` variable explicitly in the body of the function. In some cases, the beginning of the function was changed to refer to FOO so as to delay the binding to a nearby `let` when I could ensure that it did not make a difference. - Add an underscore in front of unused vars or comment them out altogether. - Replace unused `err` arg to `condition-case` with nil. Plus the additional itemized changes below. * lisp/calc/calc-map.el (calcFunc-reducer): * lisp/calc/calc-arith.el (math-setup-declarations): * lisp/calc/calc-help.el (calc-full-help, calc-help-index-entries) (calc-full-help): Use `ignore-errors`. * lisp/calc/calc-embed.el (calc-embedded-modes-change): Declare `the-language` and `the-display-just` as dynamically scoped. * lisp/calc/calc-forms.el (math-setup-year-holidays): Use `dolist`. * lisp/calc/calc-graph.el (calc-graph-set-styles): Use `symbol-value` rather than `eval.` (calc-graph-delete-temps, calc-graph-set-styles): Use ignore-errors. * lisp/calc/calc-macs.el (calc-with-trail-buffer): Add artificial use of `save-buf` to silence compiler warnings in all the cases where `body` doesn't make use of it. * lisp/calc/calc-math.el (math-largest-emacs-expt) (math-smallest-emacs-expt, math-use-emacs-fn): Use ignore-errors. * lisp/calc/calc-mode.el (calc-total-algebraic-mode): Remove "P" from interactive spec since it's not used anyway. * lisp/calc/calc-rewr.el (calc-match): Simplify. * lisp/calc/calc.el (calc-buffer): Give it a global nil value, so it's automatically declared dynbound in any file that requires `calc`. (calcDigit-nondigit): Adjust accordingly. * lisp/calc/calcalg2.el (calcFunc-table): Declare `var-dummy` as dynbound. (math-scan-for-limits): Comment out dead code. * lisp/calc/calcalg3.el (math-general-fit): Declare `var-YVAL` and `var-YVALX` as dynbound.
182 lines
4.8 KiB
EmacsLisp
182 lines
4.8 KiB
EmacsLisp
;;; calc-trail.el --- functions for manipulating the Calc "trail" -*- lexical-binding:t -*-
|
|
|
|
;; Copyright (C) 1990-1993, 2001-2020 Free Software Foundation, Inc.
|
|
|
|
;; Author: David Gillespie <daveg@synaptics.com>
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; Code:
|
|
|
|
;; This file is autoloaded from calc-ext.el.
|
|
|
|
(require 'calc-ext)
|
|
(require 'calc-macs)
|
|
|
|
;;; Trail commands.
|
|
|
|
(defun calc-trail-in ()
|
|
(interactive)
|
|
(let ((win (get-buffer-window (calc-trail-display t))))
|
|
(and win (select-window win))))
|
|
|
|
(defun calc-trail-out ()
|
|
(interactive)
|
|
(calc-select-buffer)
|
|
(let ((win (get-buffer-window (current-buffer))))
|
|
(if win
|
|
(progn
|
|
(select-window win)
|
|
(calc-align-stack-window))
|
|
(calc))))
|
|
|
|
(defun calc-trail-next (n)
|
|
(interactive "p")
|
|
(calc-with-trail-buffer
|
|
(forward-line n)
|
|
(calc-trail-here)))
|
|
|
|
(defun calc-trail-previous (n)
|
|
(interactive "p")
|
|
(calc-with-trail-buffer
|
|
(forward-line (- n))
|
|
(calc-trail-here)))
|
|
|
|
(defun calc-trail-first (n)
|
|
(interactive "p")
|
|
(calc-with-trail-buffer
|
|
(goto-char (point-min))
|
|
(forward-line n)
|
|
(calc-trail-here)))
|
|
|
|
(defun calc-trail-last (n)
|
|
(interactive "p")
|
|
(calc-with-trail-buffer
|
|
(goto-char (point-max))
|
|
(forward-line (- n))
|
|
(calc-trail-here)))
|
|
|
|
(defun calc-trail-scroll-left (n)
|
|
(interactive "P")
|
|
(let ((curwin (selected-window)))
|
|
(calc-with-trail-buffer
|
|
(unwind-protect
|
|
(progn
|
|
(select-window (get-buffer-window (current-buffer)))
|
|
(calc-scroll-left n))
|
|
(select-window curwin)))))
|
|
|
|
(defun calc-trail-scroll-right (n)
|
|
(interactive "P")
|
|
(let ((curwin (selected-window)))
|
|
(calc-with-trail-buffer
|
|
(unwind-protect
|
|
(progn
|
|
(select-window (get-buffer-window (current-buffer)))
|
|
(calc-scroll-right n))
|
|
(select-window curwin)))))
|
|
|
|
(defun calc-trail-forward (n)
|
|
(interactive "p")
|
|
(calc-with-trail-buffer
|
|
(forward-line (* n (1- (window-height))))
|
|
(calc-trail-here)))
|
|
|
|
(defun calc-trail-backward (n)
|
|
(interactive "p")
|
|
(calc-with-trail-buffer
|
|
(forward-line (- (* n (1- (window-height)))))
|
|
(calc-trail-here)))
|
|
|
|
(defun calc-trail-isearch-forward ()
|
|
(interactive)
|
|
(calc-with-trail-buffer
|
|
(let ((win (get-buffer-window (current-buffer)))
|
|
pos)
|
|
(save-window-excursion
|
|
(select-window win)
|
|
(isearch-forward)
|
|
(setq pos (point)))
|
|
(goto-char pos)
|
|
(set-window-point win pos)
|
|
(calc-trail-here))))
|
|
|
|
(defun calc-trail-isearch-backward ()
|
|
(interactive)
|
|
(calc-with-trail-buffer
|
|
(let ((win (get-buffer-window (current-buffer)))
|
|
pos)
|
|
(save-window-excursion
|
|
(select-window win)
|
|
(isearch-backward)
|
|
(setq pos (point)))
|
|
(goto-char pos)
|
|
(set-window-point win pos)
|
|
(calc-trail-here))))
|
|
|
|
(defun calc-trail-yank (arg)
|
|
(interactive "P")
|
|
(calc-wrapper
|
|
(or arg (calc-set-command-flag 'hold-trail))
|
|
(calc-enter-result 0 "yank"
|
|
(calc-with-trail-buffer
|
|
(if arg
|
|
(forward-line (- (prefix-numeric-value arg))))
|
|
(if (or (looking-at "Emacs Calc")
|
|
(looking-at "----")
|
|
(looking-at " ? ? ?[^ \n]* *$")
|
|
(looking-at "..?.?$"))
|
|
(error "Can't yank that line"))
|
|
(if (looking-at ".*, \\.\\.\\., ")
|
|
(error "Can't yank (vector was abbreviated)"))
|
|
(forward-char 4)
|
|
(search-forward " ")
|
|
(let* ((next (save-excursion (forward-line 1) (point)))
|
|
(str (buffer-substring (point) (1- next)))
|
|
(val (with-current-buffer save-buf
|
|
(math-read-plain-expr str))))
|
|
(if (eq (car-safe val) 'error)
|
|
(error "Can't yank that line: %s" (nth 2 val))
|
|
val))))))
|
|
|
|
(defun calc-trail-marker (str)
|
|
(interactive "sText to insert in trail: ")
|
|
(calc-with-trail-buffer
|
|
(forward-line 1)
|
|
(let ((buffer-read-only nil))
|
|
(insert "---- " str "\n"))
|
|
(forward-line -1)
|
|
(calc-trail-here)))
|
|
|
|
(defun calc-trail-kill (n)
|
|
(interactive "p")
|
|
(calc-with-trail-buffer
|
|
(let ((buffer-read-only nil))
|
|
(save-restriction
|
|
(narrow-to-region ; don't delete "Emacs Trail" header
|
|
(save-excursion
|
|
(goto-char (point-min))
|
|
(forward-line 1)
|
|
(point))
|
|
(point-max))
|
|
(kill-line n)))
|
|
(calc-trail-here)))
|
|
|
|
(provide 'calc-trail)
|
|
|
|
;;; calc-trail.el ends here
|