0590224343
* lisp/erc/erc.el (erc-password): Deprecate variable only used by `erc-select-read-args'. Server passwords are primarily used as surrogates for other forms of authentication. Such use is common but nonstandard and often discouraged in favor of the de facto standard, SASL. Folks in the habit of invoking `erc(-tls)' interactively should be encouraged to use auth-source instead. (erc-select-read-args): Before this change, `erc-select-read-args' offered to use the value of a non-nil `erc-password' as the :password argument for `erc' and `erc-tls', referring to it as the "default" password. And when `erc-prompt-for-password' was nil and `erc-password' wasn't, the latter was passed along unconditionally. This only further complicated an already confusing situation for new users, who in most cases shouldn't be worried about sending a PASS command at all. Until SASL arrives, they should provide server passwords manually or learn to use auth-source. (erc-auth-source-server-function, erc-auth-source-join-function): New user options for retrieving a password externally, ostensibly by calling `auth-source-search'. (erc--auth-source-determine-params-defaults): New helper for `erc--auth-source-search' with potential for exporting publicly in the future. Favors :host and :port fields above others. Prioritizes network IDs over announced servers and dialed endpoints. (erc--auth-source-determine-params-merge): Add new function for merging contextual and default parameters. This is another contender for possible exporting. (erc--auth-source-search): New function for consulting auth-source and sorting the result as filtered and prioritized by the previously mentioned helpers. (erc-auth-source-search): New function to serve as default value for auth-source query-function options. (erc-server-join-channel): Use user option for consulting auth-source facility. Also accept nil for first argument (instead of server). (erc-cmd-JOIN): Use above-mentioned facilities when joining new channel. Omit server when calling `erc-server-join-channel'. Don't filter target buffers twice. Don't call `switch-to-buffer', which would create phantom buffers with names like target/server that were never used. IOW, only switch to existing target buffers. (erc--compute-server-password): Add new helper function for determining password. (erc-open, erc-determine-parameters): Move password figuring from the first to the latter. * lisp/erc/erc-services.el (erc-auth-source-services-function): Add new option for consulting auth-source in a NickServ context. (erc-nickserv-get-password): Pass network-context ID, when looking up password in `erc-nickserv-passwords' and when formatting prompt for user input. (erc-nickserv-passwords): Add comment to custom option definition type tag. * test/lisp/erc/erc-services-tests.el: Add new test file for above changes. For now, stash auth-source-related tests here until a suitable home can be found. * lisp/erc/erc-join.el (erc-autojoin--join): Don't pass session-like entity from `erc-autojoin-channels-alist' match to `erc-server-join-channel'. Allow that function to decide for itself which host to look up if necessary. * test/lisp/erc/resources/base/auth-source/foonet.eld: New file. * test/lisp/erc/resources/base/auth-source/nopass.eld: New file. * test/lisp/erc/resources/erc-scenarios-common.el: New file. * test/lisp/erc/resources/services/auth-source/libera.eld: New file. * test/lisp/erc/erc-scenarios-auth-source.el: New file. * test/lisp/erc/erc-scenarios-base-reuse-buffers.el: New file. * test/lisp/erc/erc-scenarios-join-auth-source.el: New file. * test/lisp/erc/resources/base/reuse-buffers/channel/barnet.eld: New file. * test/lisp/erc/resources/base/reuse-buffers/channel/foonet.eld: New file. * test/lisp/erc/resources/join/auth-source/foonet.eld: New file. (Bug#48598)
178 lines
7.6 KiB
EmacsLisp
178 lines
7.6 KiB
EmacsLisp
;;; erc-scenarios-auth-source.el --- auth-source scenarios -*- lexical-binding: t -*-
|
|
|
|
;; Copyright (C) 2022 Free Software Foundation, Inc.
|
|
;;
|
|
;; This file is part of GNU Emacs.
|
|
;;
|
|
;; This program is free software: you can redistribute it and/or
|
|
;; modify it under the terms of the GNU General Public License as
|
|
;; published by the Free Software Foundation, either version 3 of the
|
|
;; License, or (at your option) any later version.
|
|
;;
|
|
;; This program is distributed in the hope that it will be useful, but
|
|
;; WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
|
|
;; General Public License for more details.
|
|
;;
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with this program. If not, see
|
|
;; <https://www.gnu.org/licenses/>.
|
|
|
|
;; Commentary:
|
|
;;
|
|
;; For practical reasons (mainly lack of imagination), this file
|
|
;; contains tests for both server-password and NickServ contexts.
|
|
|
|
(require 'ert-x)
|
|
(eval-and-compile
|
|
(let ((load-path (cons (ert-resource-directory) load-path)))
|
|
(require 'erc-scenarios-common)))
|
|
|
|
(eval-when-compile (require 'erc-join)
|
|
(require 'erc-services))
|
|
|
|
(defun erc-scenarios-common--auth-source (id dialog &rest rest)
|
|
(push "machine GNU.chat port %d user \"#chan\" password spam" rest)
|
|
(erc-scenarios-common-with-cleanup
|
|
((erc-scenarios-common-dialog "base/auth-source")
|
|
(dumb-server (erc-d-run "localhost" t dialog))
|
|
(port (process-contact dumb-server :service))
|
|
(ents `(,@(mapcar (lambda (fmt) (format fmt port)) rest)
|
|
"machine MyHost port irc password 123"))
|
|
(netrc-file (make-temp-file "auth-source-test" nil nil
|
|
(string-join ents "\n")))
|
|
(auth-sources (list netrc-file))
|
|
(auth-source-do-cache nil)
|
|
(erc-scenarios-common-extra-teardown (lambda ()
|
|
(delete-file netrc-file))))
|
|
|
|
(ert-info ("Connect")
|
|
(with-current-buffer (erc :server "127.0.0.1"
|
|
:port port
|
|
:nick "tester"
|
|
:full-name "tester"
|
|
:id id)
|
|
(should (string= (buffer-name) (if id
|
|
(symbol-name id)
|
|
(format "127.0.0.1:%d" port))))
|
|
(erc-d-t-wait-for 5 (eq erc-network 'FooNet))))))
|
|
|
|
(ert-deftest erc-scenarios-base-auth-source-server--dialed ()
|
|
:tags '(:expensive-test)
|
|
(erc-scenarios-common--auth-source
|
|
nil 'foonet
|
|
"machine GNU.chat port %d user tester password fake"
|
|
"machine FooNet port %d user tester password fake"
|
|
"machine 127.0.0.1 port %d user tester password changeme"
|
|
"machine 127.0.0.1 port %d user imposter password fake"))
|
|
|
|
(ert-deftest erc-scenarios-base-auth-source-server--netid ()
|
|
:tags '(:expensive-test)
|
|
(erc-scenarios-common--auth-source
|
|
'MySession 'foonet
|
|
"machine MySession port %d user tester password changeme"
|
|
"machine 127.0.0.1 port %d user tester password fake"
|
|
"machine FooNet port %d user tester password fake"))
|
|
|
|
(ert-deftest erc-scenarios-base-auth-source-server--netid-custom ()
|
|
:tags '(:expensive-test)
|
|
(let ((erc-auth-source-server-function
|
|
(lambda (&rest _) (erc-auth-source-search :host "MyHost"))))
|
|
(erc-scenarios-common--auth-source
|
|
'MySession 'foonet
|
|
"machine 127.0.0.1 port %d user tester password fake"
|
|
"machine MyHost port %d user tester password changeme"
|
|
"machine MySession port %d user tester password fake")))
|
|
|
|
(ert-deftest erc-scenarios-base-auth-source-server--nopass ()
|
|
:tags '(:expensive-test)
|
|
(let (erc-auth-source-server-function)
|
|
(erc-scenarios-common--auth-source nil 'nopass)))
|
|
|
|
(ert-deftest erc-scenarios-base-auth-source-server--nopass-netid ()
|
|
:tags '(:expensive-test)
|
|
(let (erc-auth-source-server-function)
|
|
(erc-scenarios-common--auth-source 'MySession 'nopass)))
|
|
|
|
;; Identify via auth source with no initial password
|
|
|
|
(defun erc-scenarios-common--services-auth-source (&rest rest)
|
|
(erc-scenarios-common-with-cleanup
|
|
((erc-scenarios-common-dialog "services/auth-source")
|
|
(erc-server-flood-penalty 0.1)
|
|
(dumb-server (erc-d-run "localhost" t 'libera))
|
|
(port (process-contact dumb-server :service))
|
|
(ents `(,@(mapcar (lambda (fmt) (format fmt port)) rest)
|
|
"machine MyHost port irc password 123"))
|
|
(netrc-file (make-temp-file "auth-source-test" nil nil
|
|
(string-join ents "\n")))
|
|
(auth-sources (list netrc-file))
|
|
(auth-source-do-cache nil)
|
|
(erc-modules (cons 'services erc-modules))
|
|
(erc-use-auth-source-for-nickserv-password t) ; do consult for NickServ
|
|
(expect (erc-d-t-make-expecter))
|
|
(erc-scenarios-common-extra-teardown (lambda ()
|
|
(delete-file netrc-file))))
|
|
|
|
(cl-letf (((symbol-function 'read-passwd)
|
|
(lambda (&rest _) (error "Unexpected read-passwd call"))))
|
|
(ert-info ("Connect without password")
|
|
(with-current-buffer (erc :server "127.0.0.1"
|
|
:port port
|
|
:nick "tester"
|
|
:full-name "tester")
|
|
(should (string= (buffer-name) (format "127.0.0.1:%d" port)))
|
|
(erc-d-t-wait-for 8 (eq erc-network 'Libera.Chat))
|
|
(funcall expect 3 "This nickname is registered.")
|
|
(funcall expect 3 "You are now identified")
|
|
(funcall expect 3 "Last login from")
|
|
(erc-cmd-QUIT ""))))
|
|
|
|
(erc-services-mode -1)
|
|
|
|
(should-not (memq 'services erc-modules))))
|
|
|
|
;; These tests are about authenticating to nick services
|
|
|
|
(ert-deftest erc-scenarios-services-auth-source--network ()
|
|
:tags '(:expensive-test)
|
|
;; Skip consulting auth-source for the server password (PASS).
|
|
(let (erc-auth-source-server-function)
|
|
(erc-scenarios-common--services-auth-source
|
|
"machine 127.0.0.1 port %d user tester password spam"
|
|
"machine zirconium.libera.chat port %d user tester password fake"
|
|
"machine Libera.Chat port %d user tester password changeme")))
|
|
|
|
(ert-deftest erc-scenarios-services-auth-source--network-connect-lookup ()
|
|
:tags '(:expensive-test)
|
|
;; Do consult auth-source for the server password (and find nothing)
|
|
(erc-scenarios-common--services-auth-source
|
|
"machine zirconium.libera.chat port %d user tester password fake"
|
|
"machine Libera.Chat port %d user tester password changeme"))
|
|
|
|
(ert-deftest erc-scenarios-services-auth-source--announced ()
|
|
:tags '(:expensive-test)
|
|
(let (erc-auth-source-server-function)
|
|
(erc-scenarios-common--services-auth-source
|
|
"machine 127.0.0.1 port %d user tester password spam"
|
|
"machine zirconium.libera.chat port %d user tester password changeme")))
|
|
|
|
(ert-deftest erc-scenarios-services-auth-source--dialed ()
|
|
:tags '(:expensive-test)
|
|
;; Support legacy host -> domain name
|
|
;; (likely most common in real configs)
|
|
(let (erc-auth-source-server-function)
|
|
(erc-scenarios-common--services-auth-source
|
|
"machine 127.0.0.1 port %d user tester password changeme")))
|
|
|
|
(ert-deftest erc-scenarios-services-auth-source--custom ()
|
|
:tags '(:expensive-test)
|
|
(let (erc-auth-source-server-function
|
|
(erc-auth-source-services-function
|
|
(lambda (&rest _) (erc-auth-source-search :host "MyAccount"))))
|
|
(erc-scenarios-common--services-auth-source
|
|
"machine zirconium.libera.chat port %d user tester password spam"
|
|
"machine MyAccount port %d user tester password changeme"
|
|
"machine 127.0.0.1 port %d user tester password fake")))
|
|
|
|
;;; erc-scenarios-auth-source.el ends here
|