d1a1c7e649
* profiler.el (profiler): Add missing group :version tag. * avoid.el (mouse-avoidance-banish-position): * proced.el (proced-renice-command): * calc/calc.el (calc-ensure-consistent-units): * calendar/icalendar.el (icalendar-import-format-uid): * net/tramp.el (tramp-save-ad-hoc-proxies): * progmodes/bug-reference.el (bug-reference-bug-regexp): * progmodes/flymake.el (flymake-error-bitmap) (flymake-warning-bitmap, flymake-fringe-indicator-position): * progmodes/sh-script.el (sh-indent-after-continuation): * progmodes/verilog-mode.el (verilog-auto-template-warn-unused) (verilog-before-save-font-hook, verilog-after-save-font-hook): * progmodes/vhdl-mode.el (vhdl-makefile-default-targets) (vhdl-array-index-record-field-in-sensitivity-list) (vhdl-indent-comment-like-next-code-line): * textmodes/reftex-vars.el (reftex-ref-style-alist) (reftex-ref-macro-prompt, reftex-ref-style-default-list) (reftex-cite-key-separator, reftex-create-bibtex-header) (reftex-create-bibtex-footer): * textmodes/rst.el (rst-new-adornment-down, rst-indent-field) (rst-indent-literal-normal, rst-indent-literal-minimized) (rst-indent-comment): Add missing custom :version tags. * cedet/semantic/complete.el (semantic-displayor-tooltip-mode) (semantic-displayor-tooltip-initial-max-tags) (semantic-displayor-tooltip-max-tags): Add missing custom :version tags. * cedet/ede/linux.el (project-linux): Add missing group :version tag. * cedet/semantic/complete.el (semantic-displayor-tooltip-max-tags): Doc fix. * erc/erc.el (erc-lurker): * erc/erc-desktop-notifications.el (erc-notifications): Add missing group :version tags. * gnus/gnus-notifications.el (gnus-notifications): Add missing group :version tag. * gnus/gnus-msg.el (gnus-gcc-pre-body-encode-hook) (gnus-gcc-post-body-encode-hook): * gnus/gnus-sync.el (gnus-sync-lesync-name) (gnus-sync-lesync-install-topics): Add missing custom :version tags.
91 lines
3.3 KiB
EmacsLisp
91 lines
3.3 KiB
EmacsLisp
;; erc-desktop-notifications.el -- Send notification on PRIVMSG or mentions
|
|
|
|
;; Copyright (C) 2012 Free Software Foundation, Inc.
|
|
|
|
;; Author: Julien Danjou <julien@danjou.info>
|
|
;; Keywords: comm
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; This implements notifications using `notifications-notify' on
|
|
;; PRIVMSG received and on public nickname mentions.
|
|
|
|
;;; Code:
|
|
|
|
(require 'erc)
|
|
(require 'xml)
|
|
(require 'notifications)
|
|
(require 'erc-match)
|
|
(require 'dbus)
|
|
|
|
(defgroup erc-notifications nil
|
|
"Send notifications on PRIVMSG or mentions."
|
|
:version "24.3"
|
|
:group 'erc)
|
|
|
|
(defvar erc-notifications-last-notification nil
|
|
"Last notification id.")
|
|
|
|
(defcustom erc-notifications-icon nil
|
|
"Icon to use for notification."
|
|
:group 'erc-notifications
|
|
:type 'file)
|
|
|
|
(defun erc-notifications-notify (nick msg)
|
|
"Notify that NICK send some MSG.
|
|
This will replace the last notification sent with this function."
|
|
(dbus-ignore-errors
|
|
(setq erc-notifications-last-notification
|
|
(notifications-notify :title (xml-escape-string nick)
|
|
:body (xml-escape-string msg)
|
|
:replaces-id erc-notifications-last-notification
|
|
:app-icon erc-notifications-icon))))
|
|
|
|
(defun erc-notifications-PRIVMSG (proc parsed)
|
|
(let ((nick (car (erc-parse-user (erc-response.sender parsed))))
|
|
(target (car (erc-response.command-args parsed)))
|
|
(msg (erc-response.contents parsed)))
|
|
(when (and (erc-current-nick-p target)
|
|
(not (and (boundp 'erc-track-exclude)
|
|
(member nick erc-track-exclude)))
|
|
(not (erc-is-message-ctcp-and-not-action-p msg)))
|
|
(erc-notifications-notify nick msg)))
|
|
;; Return nil to continue processing by ERC
|
|
nil)
|
|
|
|
(defun erc-notifications-notify-on-match (match-type nickuserhost msg)
|
|
(when (eq match-type 'current-nick)
|
|
(let ((nick (nth 0 (erc-parse-user nickuserhost))))
|
|
(unless (or (string-match-p "^Server:" nick)
|
|
(when (boundp 'erc-track-exclude)
|
|
(member nick erc-track-exclude)))
|
|
(erc-notifications-notify nick msg)))))
|
|
|
|
;;;###autoload(autoload 'erc-notifications-mode "erc-desktop-notifications" "" t)
|
|
(define-erc-module notifications nil
|
|
"Send notifications on private message reception and mentions."
|
|
;; Enable
|
|
((add-hook 'erc-server-PRIVMSG-functions 'erc-notifications-PRIVMSG)
|
|
(add-hook 'erc-text-matched-hook 'erc-notifications-notify-on-match))
|
|
;; Disable
|
|
((remove-hook 'erc-server-PRIVMSG-functions 'erc-notifications-PRIVMSG)
|
|
(remove-hook 'erc-text-matched-hook 'erc-notifications-notify-on-match)))
|
|
|
|
(provide 'erc-desktop-notifications)
|
|
|
|
;;; erc-desktop-notifications.el ends here
|