daa4e0120d
* lisp/gnus/gnus-group.el (features): Use `dlet`. (gnus-tmp-level, gnus-tmp-marked, gnus-tmp-group): Declare vars. (gnus-group-insert-group-line): Bind dynbound vars via `let` rather than as formal args. Bind `number` as dynbound. (gnus-visual, gnus-score-find-score-files-function) (gnus-home-score-file, gnus-apply-kill-hook) (gnus-summary-expunge-below): Declare vars. (gnus-group-restart, gnus-group-list-plus): Fix `interactive` spec since the arg is unused. * lisp/gnus/mail-source.el (mail-source-bind, mail-source-bind-common): Use `dlet` and suppress the warnings about the non-prefixed dynbound vars. (mail-source-set-1): Remove unused var `auth-info`. (mail-source-call-script): Remove unused var `background`. (mail-source-fetch-pop, mail-source-check-pop): Bind pop3 vars with `dlet`. * lisp/gnus/gnus-int.el (mail-source-plugged, gnus-inhibit-demon): Declare vars. (gnus-server-opened, gnus-status-message) (gnus-open-server, gnus-close-server, gnus-request-list) (gnus-finish-retrieve-group-infos, gnus-retrieve-group-data-early) (gnus-request-list-newsgroups, gnus-request-newgroups) (gnus-request-regenerate, gnus-request-compact, gnus-request-group) (gnus-retrieve-groups, gnus-request-post, gnus-request-expunge-group) (gnus-request-scan, gnus-request-update-info, gnus-request-marks) (gnus-request-accept-article, gnus-request-create-group) (gnus-asynchronous-p, gnus-remove-denial): Bind `gnus-command-method` via `let` rather than as formal args. * lisp/gnus/gnus-topic.el (gnus-topic-insert-topic-line): Pass documented vars to eval for `gnus-topic-line-format-spec`. * lisp/gnus/message.el (message-yank-original): Use `cl-progv` rather than `eval` to bind the vars from `message-cite-style`. * lisp/gnus/mml.el (mml-parse-1): Use `apply` instead of `eval`. (gnus-newsgroup-name, gnus-displaying-mime, gnus-newsgroup-name) (gnus-article-prepare-hook, gnus-newsgroup-charset) (gnus-original-article-buffer, gnus-message-buffer) (message-this-is-news, message-this-is-mail): Declare vars. * lisp/gnus/deuglify.el (gnus-outlook-rearrange-article): Remove unused var `cite-marks`. * lisp/gnus/gnus-art.el (ansi-color-context-region): Declare var. (gnus-mime-display-attachment-buttons-in-header): Move declaration before first use. (gnus-mime-display-alternative): Remove unused var `from`. * lisp/gnus/gnus-bookmark.el (gnus-bookmark-bmenu-list): Remove unused var `start` `end`. * lisp/gnus/gnus-cache.el (gnus-article-decode-hook) (nnml-generate-active-function): Declare var. * lisp/gnus/gnus-cite.el (gnus-message-citation-mode): Remove unused var `keywords`. * lisp/gnus/gnus-cloud.el (gnus-cloud-encode-data): Remove unused var `cipher`. (gnus-cloud-ensure-cloud-group): Remove unused var `method`. * lisp/gnus/gnus-delay.el (gnus-delay-article): Remove unused var `days`. * lisp/gnus/gnus-html.el (gnus-html-wash-images): Remove unused vars `tag`, `string`, and `images`. (gnus-html-wash-tags): Remove unused vars `string` and `images`. * lisp/gnus/gnus-msg.el (gnus-msg-mail): Remove unused var `group-name`. (gnus-group-mail, gnus-group-news, gnus-summary-mail-other-window) (gnus-summary-news-other-window): Remove unused vars `group` and `buffer`. (gnus-configure-posting-styles): Remove unused vars `style` and `attribute`. * lisp/gnus/gnus-picon.el (gnus-picon-find-face): Remove unused vars `database`, `directory`, and `instance`. (gnus-picon-transform-newsgroups): Remove unused var `point`. * lisp/gnus/gnus-range.el (gnus-range-difference): Remove unused var `safe`. * lisp/gnus/gnus-score.el (gnus-score-load-file): Remove unused var `score-fn`. * lisp/gnus/gnus-sum.el (message-options-set-recipient): Declare var. * lisp/gnus/gnus-undo.el (gnus-undo): Fix docstring lie. * lisp/gnus/gnus-util.el (print-string-length) (iswitchb-make-buflist-hook): Declare vars. (gnus-emacs-version): Remove unused var `codename`. (gnus-rename-file): Remove unused vars `old-name` and `new-name`. * lisp/gnus/gnus-uu.el (gnus-uu-yenc-article): Remove unused var `start-char`. (gnus-asynchronous): Declare var. * lisp/gnus/mm-partial.el (gnus-displaying-mime): Declare var. (mm-inline-partial): Remove unused var `buffer`. * lisp/gnus/mm-view.el (w3m-force-redisplay, w3m-safe-url-regexp) (gnus-displaying-mime, gnus-original-article-buffer) (gnus-article-prepare-hook): Declare vars. * lisp/gnus/mml-smime.el (mml-smime-epg-encrypt): Remove unused var `boundary`. (mml-smime-epg-verify): Remove unused vars `plain` and `signature-file`. * lisp/gnus/mml1991.el (pgg-text-mode): Declare var. * lisp/gnus/mml2015.el (pgg-text-mode): Declare var. (mml2015-pgg-decrypt): Remove unused var `result`. (mml2015-epg-key-image-to-string): Remove unused var `error`. (mml2015-epg-decrypt): Remove unused var `result`. (mml2015-epg-verify): Remove unused vars `plain` and `signature-file`. * lisp/gnus/nnbabyl.el (nnml-current-directory): Declare var. * lisp/gnus/nndiary.el (nndiary-files): Move declaration before first use. * lisp/gnus/nnfolder.el (nnfolder-request-accept-article): Remove unused var `buf`. * lisp/gnus/nnmail.el (nnmail-parse-active): Remove unused var `err`. * lisp/gnus/nnmairix.el (nnmairix-request-group): Remove unused var `args`. (nnmairix-request-create-group): Remove unused var `info`. (nnmairix-request-list): Remove unused var `folder`. (nnmairix-request-set-mark): Remove unused var `propto`. (nnmairix-request-set-mark): Remove unused vars `number` and `method`. (nnmairix-close-group): Remove unused var `method`. (nnmairix-create-search-group-from-message): Remove unused var `cq`. (nnmairix-create-server-and-default-group): Remove unused var `create`. (nnmairix-purge-old-groups): Remove unused var `folder`. (nnmairix-remove-tick-mark-original-article, nnmairix-get-valid-servers): Remove unused var `cur`. (nnmairix-replace-group-and-numbers): Remove unused var `header`. (nnmairix-goto-original-article): Remove unused var `rval`. (nnmairix-widget-create-query): Remove unused var `allwidgets`. * lisp/gnus/nnmbox.el (nnml-current-directory): Declare var. * lisp/gnus/nnmh.el (nnmh-toplev): Move declaration before first use. (nnmh-request-list-1): Remove unused var `rdir`. * lisp/gnus/nnml.el (nnml-generate-nov-file): Remove unused var `file`. * lisp/gnus/nnrss.el (nnrss-request-article): Remove unused var `post`. (nnrss-request-article): Remove unused var `fn`. (nnrss-check-group): Remove unused var `rdf-ns`. * lisp/gnus/nnweb.el (nnweb-request-article): Remove unused var `active`. (nnweb-google-parse-1): Remove unused var `Score`. * lisp/gnus/spam-stat.el (spam-stat-error-holder): Remove var. (spam-stat-buffer-words-with-scores): Remove unused var `word`. (spam-stat-score-buffer): Remove unused var `spam-stat-error-holder`. (spam-stat-split-fancy): Use `err` instead of `spam-stat-error-holder`. * lisp/gnus/spam-wash.el (spam-wash): Remove unused var `handle`. * lisp/gnus/spam.el (spam-copy-or-move-routine): Remove unused vars `article` and `mark`. (spam-register-routine): Remove unused var `article`. (spam-log-undo-registration): Remove unused var `found`. (spam-ifile-register-with-ifile): Remove unused var `parameters`. (spam-check-stat): Remove unused vars `category` and `return`. (spam-parse-list): Remove unused var `found`. (spam-filelist-register-routine): Remove unused var `from`.
200 lines
8 KiB
EmacsLisp
200 lines
8 KiB
EmacsLisp
;; gnus-notifications.el -- Send notification on new message in Gnus -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2012-2021 Free Software Foundation, Inc.
|
|
|
|
;; Author: Julien Danjou <julien@danjou.info>
|
|
;; Keywords: news
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; This implements notifications using `notifications-notify' on new
|
|
;; messages received.
|
|
;; Use (add-hook 'gnus-after-getting-new-news-hook #'gnus-notifications)
|
|
;; to get notifications just after getting the new news.
|
|
|
|
;;; Code:
|
|
|
|
(ignore-errors
|
|
(require 'notifications))
|
|
(require 'gnus-sum)
|
|
(require 'gnus-group)
|
|
(require 'gnus-int)
|
|
(require 'gnus-art)
|
|
(require 'gnus-util)
|
|
(ignore-errors
|
|
(require 'google-contacts)) ; Optional
|
|
(require 'gnus-fun)
|
|
|
|
(defgroup gnus-notifications nil
|
|
"Send notifications on new message in Gnus."
|
|
:version "24.3"
|
|
:group 'gnus)
|
|
|
|
(defcustom gnus-notifications-use-google-contacts t
|
|
"Use Google Contacts to retrieve photo."
|
|
:type 'boolean)
|
|
|
|
(defcustom gnus-notifications-use-gravatar t
|
|
"Use Gravatar to retrieve photo."
|
|
:type 'boolean)
|
|
|
|
(defcustom gnus-notifications-minimum-level 1
|
|
"Minimum group level the message should have to be notified.
|
|
Any message in a group that has a greater value than this will
|
|
not get notifications."
|
|
:type 'integer)
|
|
|
|
(defcustom gnus-notifications-timeout nil
|
|
"Timeout used for notifications sent via `notifications-notify'."
|
|
:type '(choice (const :tag "Server default" nil)
|
|
(integer :tag "Milliseconds")))
|
|
|
|
(defvar gnus-notifications-sent nil
|
|
"Notifications already sent.")
|
|
|
|
(defvar gnus-notifications-id-to-msg nil
|
|
"Map notifications ids to messages.")
|
|
|
|
(defun gnus-notifications-action (id key)
|
|
(let ((group-article (assoc id gnus-notifications-id-to-msg)))
|
|
(when group-article
|
|
(let ((group (cadr group-article))
|
|
(article (nth 2 group-article)))
|
|
(cond ((string= key "read")
|
|
(gnus-fetch-group group (list article))
|
|
(select-frame-set-input-focus (selected-frame)))
|
|
((string= key "mark-read")
|
|
(gnus-update-read-articles
|
|
group
|
|
(delq article (gnus-list-of-unread-articles group)))
|
|
;; gnus-group-refresh-group
|
|
(gnus-group-update-group group)))))))
|
|
|
|
(defun gnus-notifications-notify (from subject photo-file)
|
|
"Send a notification about a new mail.
|
|
Return a notification id if any, or t on success."
|
|
(if (fboundp 'notifications-notify)
|
|
(gnus-funcall-no-warning
|
|
'notifications-notify
|
|
:title from
|
|
:body subject
|
|
:actions '("read" "Read" "mark-read" "Mark As Read")
|
|
:on-action 'gnus-notifications-action
|
|
:app-icon (gnus-funcall-no-warning
|
|
'image-search-load-path "gnus/gnus.png")
|
|
:image-path photo-file
|
|
:app-name "Gnus"
|
|
:category "email.arrived"
|
|
:timeout gnus-notifications-timeout)
|
|
(message "New message from %s: %s" from subject)
|
|
;; Don't return an id
|
|
t))
|
|
|
|
(declare-function gravatar-retrieve-synchronously "gravatar.el"
|
|
(mail-address))
|
|
|
|
(defun gnus-notifications-get-photo (mail-address)
|
|
"Get photo for mail address."
|
|
(let ((google-photo (when (and gnus-notifications-use-google-contacts
|
|
(fboundp 'google-contacts-get-photo))
|
|
(ignore-errors
|
|
(gnus-funcall-no-warning
|
|
'google-contacts-get-photo mail-address)))))
|
|
(if google-photo
|
|
google-photo
|
|
(when gnus-notifications-use-gravatar
|
|
(let ((gravatar (ignore-errors
|
|
(gravatar-retrieve-synchronously mail-address))))
|
|
(if (eq gravatar 'error)
|
|
nil
|
|
(plist-get (cdr gravatar) :data)))))))
|
|
|
|
(defun gnus-notifications-get-photo-file (mail-address)
|
|
"Get a temporary file with an image for MAIL-ADDRESS.
|
|
You have to delete the temporary image yourself using
|
|
`delete-image'.
|
|
|
|
Returns nil if no image found."
|
|
(let ((photo (gnus-notifications-get-photo mail-address)))
|
|
(when photo
|
|
(let ((photo-file (make-temp-file "gnus-notifications-photo-"))
|
|
(coding-system-for-write 'binary))
|
|
(with-temp-file photo-file
|
|
(insert photo))
|
|
photo-file))))
|
|
|
|
;;;###autoload
|
|
(defun gnus-notifications ()
|
|
"Send a notification on new message.
|
|
This check for new messages that are in group with a level lower
|
|
or equal to `gnus-notifications-minimum-level' and send a
|
|
notification using `notifications-notify' for it.
|
|
|
|
This is typically a function to add in
|
|
`gnus-after-getting-new-news-hook'"
|
|
(dolist (entry gnus-newsrc-alist)
|
|
(let ((group (car entry)))
|
|
;; Check that the group level is less than
|
|
;; `gnus-notifications-minimum-level' and the group has unread
|
|
;; messages.
|
|
(when (and (<= (gnus-group-level group) gnus-notifications-minimum-level)
|
|
(let ((unread (gnus-group-unread group)))
|
|
(and (numberp unread)
|
|
(> unread 0))))
|
|
;; Each group should have an entry in the `gnus-notifications-sent'
|
|
;; alist. If not, we add one at this time.
|
|
(let ((group-notifications (or (assoc group gnus-notifications-sent)
|
|
;; Nothing, add one and return it.
|
|
(assoc group
|
|
(add-to-list
|
|
'gnus-notifications-sent
|
|
(cons group nil))))))
|
|
(dolist (article (gnus-list-of-unread-articles group))
|
|
;; Check if the article already has been notified
|
|
(unless (memq article (cdr group-notifications))
|
|
(with-current-buffer nntp-server-buffer
|
|
(gnus-request-head article group)
|
|
(article-decode-encoded-words) ; to decode mail addresses, subjects, etc
|
|
(let* ((address-components (mail-extract-address-components
|
|
(or (mail-fetch-field "From") "")))
|
|
(address (cadr address-components)))
|
|
;; Ignore mails from ourselves
|
|
(unless (and gnus-ignored-from-addresses
|
|
address
|
|
(cond ((functionp gnus-ignored-from-addresses)
|
|
(funcall gnus-ignored-from-addresses address))
|
|
(t (string-match-p
|
|
(gnus-ignored-from-addresses)
|
|
address))))
|
|
(let* ((photo-file (gnus-notifications-get-photo-file address))
|
|
(notification-id (gnus-notifications-notify
|
|
(or (car address-components) address)
|
|
(mail-fetch-field "Subject")
|
|
photo-file)))
|
|
(when notification-id
|
|
;; Register that we did notify this message
|
|
(setcdr group-notifications (cons article (cdr group-notifications)))
|
|
(unless (eq notification-id t)
|
|
;; Register the notification id for later actions
|
|
(add-to-list 'gnus-notifications-id-to-msg (list notification-id group article))))
|
|
(when photo-file
|
|
(delete-file photo-file)))))))))))))
|
|
|
|
(provide 'gnus-notifications)
|
|
|
|
;;; gnus-notifications.el ends here
|