39d4e1ca21
* lisp/emacs-lisp/range.el: New file. * lisp/gnus/gnus-agent.el (range): (gnus-agent-synchronize-group-flags): (gnus-agent-possibly-alter-active): (gnus-agent-fetch-headers): (gnus-agent-read-agentview): (gnus-agent-fetch-group-1): (gnus-agent-read-p): (gnus-agent-expire-group-1): (gnus-agent-retrieve-headers): Adjust callers. * lisp/gnus/gnus-art.el (range): (gnus-article-describe-bindings): * lisp/gnus/gnus-cloud.el (range): (gnus-cloud-available-chunks): * lisp/gnus/gnus-draft.el (gnus-group-send-queue): * lisp/gnus/gnus-group.el (range): (gnus-group-line-format-alist): (gnus-number-of-unseen-articles-in-group): (gnus-group-update-eval-form): (gnus-group-read-group): (gnus-group-delete-articles): (gnus-group-catchup): (gnus-group-expire-articles-1): (gnus-add-marked-articles): * lisp/gnus/gnus-int.el (gnus-request-marks): * lisp/gnus/gnus-kill.el (gnus-apply-kill-file-internal): * lisp/gnus/gnus-range.el (gnus-range-difference) (gnus-sorted-range-intersection, gnus-uncompress-range) (gnus-add-to-range, gnus-remove-from-range) (gnus-member-of-range, gnus-list-range-intersection) (gnus-list-range-difference, gnus-range-length, gnus-range-add) (gnus-range-map): Make into obsolete aliases. * lisp/gnus/gnus-start.el (gnus-make-articles-unread): (gnus-convert-old-ticks): (gnus-read-old-newsrc-el-file): * lisp/gnus/gnus-sum.el (gnus-select-newsgroup): (gnus-articles-to-read): (gnus-articles-to-read): (gnus-killed-articles): (gnus-adjust-marked-articles): (gnus-update-marks): (gnus-update-marks): (gnus-compute-read-articles): (gnus-list-of-read-articles): (gnus-summary-update-info): (gnus-summary-move-article): (gnus-summary-expire-articles): (gnus-update-read-articles): (gnus-summary-insert-old-articles): (gnus-summary-insert-old-articles): (gnus-summary-insert-old-articles): * lisp/gnus/mail-source.el (gnus-range): (gnus-compress-sequence): * lisp/gnus/nnheader.el (range): (gnus-range-add): (nnheader-update-marks-actions): * lisp/gnus/nnimap.el (nnimap-update-info): (nnimap-update-info): (nnimap-update-info): (nnimap-update-qresync-info): (nnimap-update-qresync-info): (nnimap-update-qresync-info): (nnimap-parse-copied-articles): * lisp/gnus/nnmaildir.el (nnmaildir-request-update-info): (nnmaildir-request-update-info): (nnmaildir-request-expire-articles): (nnmaildir-request-expire-articles): (nnmaildir-request-set-mark): * lisp/gnus/nnmairix.el (nnmairix-request-set-mark): * lisp/gnus/nnmbox.el (nnmbox-record-active-article): (nnmbox-record-deleted-article): * lisp/gnus/nnml.el (nnml-request-compact-group): * lisp/gnus/nnvirtual.el (nnvirtual-request-expire-articles): * lisp/gnus/nnselect.el (numbers-by-group): (nnselect-request-update-info): (nnselect-push-info):
325 lines
12 KiB
EmacsLisp
325 lines
12 KiB
EmacsLisp
;;; gnus-draft.el --- draft message support for Gnus -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 1997-2022 Free Software Foundation, Inc.
|
|
|
|
;; Author: Lars Magne Ingebrigtsen <larsi@gnus.org>
|
|
;; Keywords: news
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; Code:
|
|
|
|
(require 'gnus)
|
|
(require 'gnus-sum)
|
|
(require 'message)
|
|
(require 'gnus-msg)
|
|
(require 'nndraft)
|
|
(require 'gnus-agent)
|
|
|
|
;;; Draft minor mode
|
|
|
|
(defvar-keymap gnus-draft-mode-map
|
|
"D t" #'gnus-draft-toggle-sending
|
|
"e" #' gnus-draft-edit-message ;; Use `B w' for `gnus-summary-edit-article'
|
|
"D e" #'gnus-draft-edit-message
|
|
"D s" #'gnus-draft-send-message
|
|
"D S" #'gnus-draft-send-all-messages)
|
|
|
|
(defun gnus-draft-make-menu-bar ()
|
|
(unless (boundp 'gnus-draft-menu)
|
|
(easy-menu-define
|
|
gnus-draft-menu gnus-draft-mode-map ""
|
|
'("Drafts"
|
|
["Toggle whether to send" gnus-draft-toggle-sending t]
|
|
["Edit" gnus-draft-edit-message t]
|
|
["Send selected message(s)" gnus-draft-send-message t]
|
|
["Send all messages" gnus-draft-send-all-messages t]
|
|
["Delete draft" gnus-summary-delete-article t]))))
|
|
|
|
(define-minor-mode gnus-draft-mode
|
|
"Minor mode for providing a draft summary buffers.
|
|
|
|
\\{gnus-draft-mode-map}"
|
|
:lighter " Draft" :keymap gnus-draft-mode-map
|
|
(cond
|
|
((not (derived-mode-p 'gnus-summary-mode)) (setq gnus-draft-mode nil))
|
|
(gnus-draft-mode
|
|
;; Set up the menu.
|
|
(when (gnus-visual-p 'draft-menu 'menu)
|
|
(gnus-draft-make-menu-bar))
|
|
(add-hook 'gnus-summary-prepare-exit-hook #'gnus-draft-clear-marks t t))))
|
|
|
|
;;; Commands
|
|
|
|
(defun gnus-draft-toggle-sending (article)
|
|
"Toggle whether to send an article or not."
|
|
(interactive (list (gnus-summary-article-number)) gnus-summary-mode)
|
|
(if (gnus-draft-article-sendable-p article)
|
|
(progn
|
|
(push article gnus-newsgroup-unsendable)
|
|
(gnus-summary-mark-article article gnus-unsendable-mark))
|
|
(setq gnus-newsgroup-unsendable
|
|
(delq article gnus-newsgroup-unsendable))
|
|
(gnus-summary-mark-article article gnus-unread-mark))
|
|
(gnus-summary-position-point))
|
|
|
|
(defun gnus-draft-edit-message ()
|
|
"Enter a mail/post buffer to edit and send the draft."
|
|
(interactive nil gnus-summary-mode)
|
|
(let ((article (gnus-summary-article-number))
|
|
(group gnus-newsgroup-name))
|
|
(gnus-draft-check-draft-articles (list article))
|
|
(gnus-summary-mark-as-read article gnus-canceled-mark)
|
|
(gnus-draft-setup article group t)
|
|
(set-buffer-modified-p t)
|
|
(save-excursion
|
|
(save-restriction
|
|
(message-narrow-to-headers)
|
|
(message-remove-header "date")))
|
|
(let ((message-draft-headers (remq 'Date message-draft-headers)))
|
|
(save-buffer))
|
|
(let ((gnus-verbose-backends nil))
|
|
(gnus-request-expire-articles (list article) group t))
|
|
(push
|
|
(let ((buf gnus-summary-buffer))
|
|
(lambda ()
|
|
(when (gnus-buffer-live-p buf)
|
|
(with-current-buffer buf
|
|
(gnus-cache-possibly-remove-article article nil nil nil t)))))
|
|
message-send-actions)))
|
|
|
|
(defun gnus-draft-send-message (&optional n)
|
|
"Send the current draft(s).
|
|
Obeys the standard process/prefix convention."
|
|
(interactive "P" gnus-summary-mode)
|
|
(let* ((articles (gnus-summary-work-articles n))
|
|
(total (length articles))
|
|
article)
|
|
(gnus-draft-check-draft-articles articles)
|
|
(while (setq article (pop articles))
|
|
(gnus-summary-remove-process-mark article)
|
|
(unless (memq article gnus-newsgroup-unsendable)
|
|
(let ((message-sending-message
|
|
(format "Sending message %d of %d..."
|
|
(- total (length articles)) total)))
|
|
(gnus-draft-send article gnus-newsgroup-name t))
|
|
(gnus-summary-mark-article article gnus-canceled-mark)))))
|
|
|
|
(defun gnus-draft-send (article &optional group interactive)
|
|
"Send message ARTICLE."
|
|
(let* ((is-queue (or (not group)
|
|
(equal group "nndraft:queue")))
|
|
(message-syntax-checks (if interactive message-syntax-checks
|
|
'dont-check-for-anything-just-trust-me))
|
|
(message-hidden-headers nil)
|
|
(message-inhibit-body-encoding (or is-queue
|
|
message-inhibit-body-encoding))
|
|
(message-send-hook (and (not is-queue)
|
|
message-send-hook))
|
|
(message-setup-hook (and (not is-queue)
|
|
message-setup-hook))
|
|
(gnus-message-setup-hook (and (not is-queue)
|
|
gnus-message-setup-hook))
|
|
(message-signature (and (not is-queue)
|
|
message-signature))
|
|
(gnus-agent-queue-mail (and (not is-queue)
|
|
gnus-agent-queue-mail))
|
|
(rfc2047-encode-encoded-words nil)
|
|
type method move-to)
|
|
(gnus-draft-setup article (or group "nndraft:queue") nil 'dont-pop)
|
|
;; We read the meta-information that says how and where
|
|
;; this message is to be sent.
|
|
(save-restriction
|
|
(message-narrow-to-headers)
|
|
(when (re-search-forward
|
|
(concat "^" (regexp-quote gnus-agent-target-move-group-header)
|
|
":") nil t)
|
|
(skip-syntax-forward "-")
|
|
(setq move-to (buffer-substring (point) (point-at-eol)))
|
|
(message-remove-header gnus-agent-target-move-group-header))
|
|
(goto-char (point-min))
|
|
(when (re-search-forward
|
|
(concat "^" (regexp-quote gnus-agent-meta-information-header) ":")
|
|
nil t)
|
|
(setq type (ignore-errors (read (current-buffer)))
|
|
method (ignore-errors (read (current-buffer))))
|
|
(message-remove-header gnus-agent-meta-information-header)))
|
|
;; Let Agent restore any GCC lines and have message.el perform them.
|
|
(gnus-agent-restore-gcc)
|
|
;; Then we send it. If we have no meta-information, we just send
|
|
;; it and let Message figure out how.
|
|
(when (and (or (null method)
|
|
(gnus-server-opened method)
|
|
(gnus-open-server method))
|
|
(if type
|
|
(let ((message-this-is-news (eq type 'news))
|
|
(message-this-is-mail (eq type 'mail))
|
|
(gnus-post-method method)
|
|
(message-post-method method))
|
|
(if move-to
|
|
(gnus-inews-do-gcc move-to)
|
|
(message-send-and-exit)))
|
|
(if move-to
|
|
(gnus-inews-do-gcc move-to)
|
|
(message-send-and-exit))))
|
|
(let ((gnus-verbose-backends nil))
|
|
(gnus-request-expire-articles
|
|
(list article) (or group "nndraft:queue") t)))))
|
|
|
|
(defun gnus-draft-send-all-messages ()
|
|
"Send all the sendable drafts."
|
|
(interactive)
|
|
(when (or
|
|
gnus-expert-user
|
|
(gnus-y-or-n-p
|
|
"Send all drafts? "))
|
|
(gnus-uu-mark-buffer)
|
|
(gnus-draft-send-message)))
|
|
|
|
(defun gnus-group-send-queue ()
|
|
"Send all sendable articles from the queue group."
|
|
(interactive)
|
|
(when (or gnus-plugged
|
|
(not gnus-agent-prompt-send-queue)
|
|
(gnus-y-or-n-p "Gnus is unplugged; really send queue? "))
|
|
(gnus-activate-group "nndraft:queue")
|
|
(save-excursion
|
|
(let* ((articles (nndraft-articles))
|
|
(unsendable (range-uncompress
|
|
(cdr (assq 'unsend
|
|
(gnus-info-marks
|
|
(gnus-get-info "nndraft:queue"))))))
|
|
(gnus-posting-styles nil)
|
|
message-send-mail-partially-limit
|
|
(total (length articles))
|
|
article)
|
|
(while (setq article (pop articles))
|
|
(unless (memq article unsendable)
|
|
(let ((message-sending-message
|
|
(format "Sending message %d of %d..."
|
|
(- total (length articles)) total)))
|
|
(gnus-draft-send article))))))
|
|
(gnus-group-refresh-group "nndraft:queue")))
|
|
|
|
;;;###autoload
|
|
(defun gnus-draft-reminder ()
|
|
"Reminder user if there are unsent drafts."
|
|
(interactive)
|
|
(if (gnus-alive-p)
|
|
(let (active)
|
|
(catch 'continue
|
|
(dolist (group '("nndraft:drafts" "nndraft:queue"))
|
|
(setq active (gnus-activate-group group))
|
|
(if (and active (>= (cdr active) (car active)))
|
|
(if (y-or-n-p "There are unsent drafts. Confirm to exit? ")
|
|
(throw 'continue t)
|
|
(error "Stop!"))))))))
|
|
|
|
(defcustom gnus-draft-setup-hook nil
|
|
"Hook run after setting up a draft buffer."
|
|
:group 'gnus-message
|
|
:version "23.1" ;; No Gnus
|
|
:type 'hook)
|
|
|
|
|
|
(defun gnus-draft-setup (narticle group &optional restore dont-pop)
|
|
"Setup a mail draft buffer.
|
|
If DONT-POP is nil, display the buffer after setting it up."
|
|
(let (ga)
|
|
(gnus-setup-message 'forward
|
|
(let ((article narticle))
|
|
(message-mail nil nil nil nil
|
|
(if dont-pop
|
|
(lambda (buf) (set-buffer (gnus-get-buffer-create buf)))))
|
|
(let ((inhibit-read-only t))
|
|
(erase-buffer))
|
|
(if (not (gnus-request-restore-buffer article group))
|
|
(error "Couldn't restore the article")
|
|
(when (and restore
|
|
(equal group "nndraft:queue"))
|
|
(mime-to-mml))
|
|
;; Insert the separator.
|
|
(goto-char (point-min))
|
|
(search-forward "\n\n")
|
|
(forward-char -1)
|
|
(save-restriction
|
|
(narrow-to-region (point-min) (point))
|
|
(setq ga
|
|
(message-fetch-field gnus-draft-meta-information-header)))
|
|
(insert mail-header-separator)
|
|
(forward-line 1)
|
|
(message-set-auto-save-file-name))))
|
|
(gnus-backlog-remove-article group narticle)
|
|
(when (and ga
|
|
(ignore-errors (setq ga (car (read-from-string ga)))))
|
|
(setq gnus-newsgroup-name
|
|
(if (equal (car ga) "") nil (car ga)))
|
|
(gnus-configure-posting-styles)
|
|
(setq gnus-message-group-art (cons gnus-newsgroup-name (cadr ga)))
|
|
(setq message-post-method
|
|
(lambda (arg) (gnus-post-method arg (car ga))))
|
|
(unless (equal (cadr ga) "")
|
|
(dolist (article (cdr ga))
|
|
(message-add-action
|
|
`(progn
|
|
(gnus-add-mark ,(car ga) 'replied ,article)
|
|
(gnus-request-set-mark ,(car ga) (list (list (list ,article)
|
|
'add '(reply)))))
|
|
'send))))
|
|
(run-hooks 'gnus-draft-setup-hook)))
|
|
|
|
(defun gnus-draft-article-sendable-p (article)
|
|
"Say whether ARTICLE is sendable."
|
|
(not (memq article gnus-newsgroup-unsendable)))
|
|
|
|
(defun gnus-draft-check-draft-articles (articles)
|
|
"Check whether the draft articles ARTICLES are under edit."
|
|
(when (equal gnus-newsgroup-name "nndraft:drafts")
|
|
(let ((buffers (buffer-list))
|
|
file buffs buff)
|
|
(save-current-buffer
|
|
(while (and articles
|
|
(not buff))
|
|
(setq file (nndraft-article-filename (pop articles))
|
|
buffs buffers)
|
|
(while buffs
|
|
(set-buffer (setq buff (pop buffs)))
|
|
(if (and buffer-file-name
|
|
(equal (file-remote-p file)
|
|
(file-remote-p buffer-file-name))
|
|
(string-equal (file-truename buffer-file-name)
|
|
(file-truename file))
|
|
(buffer-modified-p))
|
|
(setq buffs nil)
|
|
(setq buff nil)))))
|
|
(when buff
|
|
(let* ((window (get-buffer-window buff t))
|
|
(frame (and window (window-frame window))))
|
|
(if frame
|
|
(select-frame-set-input-focus frame)
|
|
(pop-to-buffer buff t)))
|
|
(error "The draft %s is under edit" file)))))
|
|
|
|
(defun gnus-draft-clear-marks ()
|
|
(setq gnus-newsgroup-reads nil
|
|
gnus-newsgroup-marked nil
|
|
gnus-newsgroup-unreads (nndraft-articles)))
|
|
|
|
(provide 'gnus-draft)
|
|
|
|
;;; gnus-draft.el ends here
|