8051be9ac2
* lisp/eshell/em-extpipe.el (eshell-extpipe): * lisp/eshell/esh-opt.el (eshell-opt): New groups. Eshell uses these to identify modules to unload. * lisp/eshell/em-hist.el (eshell-hist-unload-hook): * lisp/eshell/em-ls.el (eshell-ls-unload-hook): * lisp/eshell/em-smart.el (eshell-smart-unload-hook): * lisp/eshell/eshell.el (eshell-unload-hook): Make obsolete and move to... * lisp/eshell/em-smart.el (em-smart-unload-function): * lisp/eshell/em-hist.el (em-hist-unload-function): * lisp/eshell/em-ls.el (em-ls-unload-function): * lisp/eshell/eshell.el (eshell-unload-function): ... these. * lisp/eshell/esh-mode.el (eshell-mode-unload-hook): * lisp/eshell/esh-module.el (eshell-module-unload-hook): Make obsolete. * lisp/eshell/em-ls (eshell-ls-enable-in-dired, eshell-ls-disable-in-dired): New functions... (eshell-ls-use-in-dired): ... use them. * lisp/eshell/esh-module.el (eshell-module--feature-name, eshell-unload-modules): New functions. (eshell-unload-extension-modules): Use 'eshell-unload-modules'. * lisp/eshell/eshell.el (eshell-unload-all-modules): Remove. * test/lisp/eshell/eshell-tests-unload.el: New file. * doc/misc/eshell.texi (Bugs and ideas): Remove item about unloading Eshell not working. * etc/NEWS: Announce this change (bug#61501).
122 lines
4.2 KiB
EmacsLisp
122 lines
4.2 KiB
EmacsLisp
;;; esh-module.el --- Eshell modules -*- lexical-binding:t -*-
|
|
|
|
;; Copyright (C) 1999-2000, 2002-2023 Free Software Foundation, Inc.
|
|
|
|
;; Author: John Wiegley <johnw@gnu.org>
|
|
;; Keywords: processes
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; Code:
|
|
|
|
(require 'esh-util)
|
|
|
|
(defgroup eshell-module nil
|
|
"The `eshell-module' group is for Eshell extension modules, which
|
|
provide optional behavior which the user can enable or disable by
|
|
customizing the variable `eshell-modules-list'."
|
|
:tag "Extension modules"
|
|
:group 'eshell)
|
|
|
|
;; load the defgroup's for the standard extension modules, so that
|
|
;; documentation can be provided when the user customize's
|
|
;; `eshell-modules-list'. We use "(progn (defgroup ..." in each file
|
|
;; to force the autoloader into including the entire defgroup, rather
|
|
;; than an abbreviated version.
|
|
(load "esh-groups" nil 'nomessage)
|
|
|
|
;;; User Variables:
|
|
|
|
(defcustom eshell-module-unload-hook
|
|
'(eshell-unload-extension-modules)
|
|
"A hook run when `eshell-module' is unloaded."
|
|
:type 'hook
|
|
:group 'eshell-module)
|
|
(make-obsolete-variable 'eshell-module-unload-hook nil "30.1")
|
|
|
|
(defcustom eshell-modules-list
|
|
'(eshell-alias
|
|
eshell-banner
|
|
eshell-basic
|
|
eshell-cmpl
|
|
eshell-dirs
|
|
eshell-extpipe
|
|
eshell-glob
|
|
eshell-hist
|
|
eshell-ls
|
|
eshell-pred
|
|
eshell-prompt
|
|
eshell-script
|
|
eshell-term
|
|
eshell-unix)
|
|
"A list of optional add-on modules to be loaded by Eshell.
|
|
Changes will only take effect in future Eshell buffers."
|
|
:type (append
|
|
(list 'set ':tag "Supported modules")
|
|
(mapcar
|
|
(lambda (modname)
|
|
(let ((modsym (intern modname)))
|
|
(list 'const
|
|
':tag (format "%s -- %s" modname
|
|
(get modsym 'custom-tag))
|
|
':link (caar (get modsym 'custom-links))
|
|
':doc (concat "\n" (get modsym 'group-documentation)
|
|
"\n ")
|
|
modsym)))
|
|
(sort (mapcar 'symbol-name
|
|
(eshell-subgroups 'eshell-module))
|
|
'string-lessp))
|
|
'((repeat :inline t :tag "Other modules" symbol)))
|
|
:group 'eshell-module)
|
|
|
|
;;; Code:
|
|
|
|
(defsubst eshell-module--feature-name (module &optional kind)
|
|
"Get the feature name for the specified Eshell MODULE."
|
|
(let ((module-name (symbol-name module))
|
|
(prefix (cond ((eq kind 'core) "esh-")
|
|
((memq kind '(extension nil)) "em-")
|
|
(t (error "unknown module kind %s" kind)))))
|
|
(if (string-match "^eshell-\\(.*\\)" module-name)
|
|
(concat prefix (match-string 1 module-name))
|
|
(error "Invalid Eshell module name: %s" module))))
|
|
|
|
(defsubst eshell-using-module (module)
|
|
"Return non-nil if a certain Eshell MODULE is in use.
|
|
The MODULE should be a symbol corresponding to that module's
|
|
customization group. Example: `eshell-cmpl' for that module."
|
|
(memq module eshell-modules-list))
|
|
|
|
(defun eshell-unload-modules (modules &optional kind)
|
|
"Try to unload the specified Eshell MODULES."
|
|
(dolist (module modules)
|
|
(let ((module-feature (intern (eshell-module--feature-name module kind))))
|
|
(when (featurep module-feature)
|
|
(message "Unloading %s..." (symbol-name module))
|
|
(condition-case-unless-debug _
|
|
(progn
|
|
(unload-feature module-feature)
|
|
(message "Unloading %s...done" (symbol-name module)))
|
|
(error (message "Unloading %s...failed" (symbol-name module))))))))
|
|
|
|
(defun eshell-unload-extension-modules ()
|
|
"Try to unload all currently-loaded Eshell extension modules."
|
|
(eshell-unload-modules (eshell-subgroups 'eshell-module)))
|
|
|
|
(provide 'esh-module)
|
|
;;; esh-module.el ends here
|