666ffc7e09
* lisp/org/ob-abc.el (org-babel-expand-body:abc): Use dolist. (org-babel-execute:abc): Fix regexp quoting. * lisp/org/ob-calc.el (org--var-syms): Rename from `var-syms'. * lisp/org/ob-lilypond.el (ly-compile-lilyfile): Remove redundant let-binding. * lisp/org/ob-table.el (sbe): Move debug declaration. * lisp/org/org-clock.el (org--msg-extra): Rename from `msg-extra'. * lisp/org/org.el (org-version): Avoid var name starting with _. (org-inhibit-startup, org-called-with-limited-levels) (org-link-search-inhibit-query, org-time-was-given) (org-end-time-was-given, org-def, org-defdecode, org-with-time): * lisp/org/org-colview.el (org-agenda-overriding-columns-format): * lisp/org/org-agenda.el (org-agenda-multi, org-depend-tag-blocked) (org-agenda-show-log-scoped): * lisp/org/ob-python.el (py-which-bufname, python-shell-buffer-name): * lisp/org/ob-haskell.el (org-export-copy-to-kill-ring): * lisp/org/ob-exp.el (org-link-search-inhibit-query): * lisp/org/ob-R.el (ess-eval-visibly-p): * lisp/org/ob-core.el (org-src-window-setup): Declare before use. (org-babel-expand-noweb-references): Remove unused `blocks-in-buffer'. * lisp/org/ox-odt.el (org-odt-hfy-face-to-css): * lisp/org/org-src.el (org-src-associate-babel-session, org-src-get-lang-mode): * lisp/org/org-bibtex.el (org-bibtex-get, org-bibtex-ask, org-bibtex) (org-bibtex-check): * lisp/org/ob-tangle.el (org-babel-tangle, org-babel-spec-to-string) (org-babel-tangle-single-block, org-babel-tangle-comment-links): * ob-table.el (sbe): * lisp/org/ob-sqlite.el (org-babel-sqlite-expand-vars): * lisp/org/ob-sql.el (org-babel-sql-expand-vars): * lisp/org/ob-shen.el (org-babel-execute:shen): * lisp/org/ob-sh.el (org-babel-execute:sh, org-babel-sh-evaluate): * lisp/org/ob-scala.el (org-babel-scala-evaluate): * lisp/org/ob-ruby.el (org-babel-ruby-table-or-string) (org-babel-ruby-evaluate): * ob-python.el (org-babel-python-table-or-string) (org-babel-python-evaluate-external-process) (org-babel-python-evaluate-session): * lisp/org/ob-picolisp.el (org-babel-execute:picolisp): * lisp/org/ob-perl.el (org-babel-perl-evaluate): * lisp/org/ob-maxima.el (org-babel-execute:maxima): * lisp/org/ob-lisp.el (org-babel-execute:lisp): * lisp/org/ob-java.el (org-babel-execute:java): * lisp/org/ob-io.el (org-babel-io-evaluate): * ob-haskell.el (org-babel-execute:haskell): * lisp/org/ob-fortran.el (org-babel-execute:fortran): * ob-exp.el (org-babel-exp-code): * lisp/org/ob-emacs-lisp.el (org-babel-execute:emacs-lisp): * lisp/org/ob-ditaa.el (org-babel-execute:ditaa): * ob-core.el (org-babel-execute-src-block, org-babel-sha1-hash) (org-babel-parse-header-arguments, org-babel-reassemble-table) (org-babel-goto-src-block-head, org-babel-mark-block) (org-babel-expand-noweb-references, org-babel-script-escape) (org-babel-process-file-name): * lisp/org/ob-clojure.el (org-babel-execute:clojure): * ob-calc.el (org-babel-execute:calc): * lisp/org/ob-awk.el (org-babel-execute:awk): * ob-abc.el (org-babel-execute:abc): * ob-R.el (org-babel-expand-body:R): * lisp/org/ob-C.el (org-babel-C-execute): Avoid deprecated ((lambda) ...).
95 lines
3.2 KiB
EmacsLisp
95 lines
3.2 KiB
EmacsLisp
;;; ob-clojure.el --- org-babel functions for clojure evaluation
|
|
|
|
;; Copyright (C) 2009-2013 Free Software Foundation, Inc.
|
|
|
|
;; Author: Joel Boehland
|
|
;; Eric Schulte
|
|
;; Keywords: literate programming, reproducible research
|
|
;; Homepage: http://orgmode.org
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;; Support for evaluating clojure code, relies on slime for all eval.
|
|
|
|
;;; Requirements:
|
|
|
|
;; - clojure (at least 1.2.0)
|
|
;; - clojure-mode
|
|
;; - slime
|
|
|
|
;; By far, the best way to install these components is by following
|
|
;; the directions as set out by Phil Hagelberg (Technomancy) on the
|
|
;; web page: http://technomancy.us/126
|
|
|
|
;;; Code:
|
|
(require 'ob)
|
|
|
|
(declare-function slime-eval "ext:slime" (sexp &optional package))
|
|
|
|
(defvar org-babel-tangle-lang-exts)
|
|
(add-to-list 'org-babel-tangle-lang-exts '("clojure" . "clj"))
|
|
|
|
(defvar org-babel-default-header-args:clojure '())
|
|
(defvar org-babel-header-args:clojure '((package . :any)))
|
|
|
|
(defun org-babel-expand-body:clojure (body params)
|
|
"Expand BODY according to PARAMS, return the expanded body."
|
|
(let* ((vars (mapcar #'cdr (org-babel-get-header params :var)))
|
|
(result-params (cdr (assoc :result-params params)))
|
|
(print-level nil) (print-length nil)
|
|
(body (org-babel-trim
|
|
(if (> (length vars) 0)
|
|
(concat "(let ["
|
|
(mapconcat
|
|
(lambda (var)
|
|
(format "%S (quote %S)" (car var) (cdr var)))
|
|
vars "\n ")
|
|
"]\n" body ")")
|
|
body))))
|
|
(cond ((or (member "code" result-params) (member "pp" result-params))
|
|
(format (concat "(let [org-mode-print-catcher (java.io.StringWriter.)] "
|
|
"(clojure.pprint/with-pprint-dispatch clojure.pprint/%s-dispatch "
|
|
"(clojure.pprint/pprint (do %s) org-mode-print-catcher) "
|
|
"(str org-mode-print-catcher)))")
|
|
(if (member "code" result-params) "code" "simple") body))
|
|
;; if (:results output), collect printed output
|
|
((member "output" result-params)
|
|
(format "(clojure.core/with-out-str %s)" body))
|
|
(t body))))
|
|
|
|
(defun org-babel-execute:clojure (body params)
|
|
"Execute a block of Clojure code with Babel."
|
|
(require 'slime)
|
|
(with-temp-buffer
|
|
(insert (org-babel-expand-body:clojure body params))
|
|
(let ((result
|
|
(slime-eval
|
|
`(swank:eval-and-grab-output
|
|
,(buffer-substring-no-properties (point-min) (point-max)))
|
|
(cdr (assoc :package params)))))
|
|
(let ((result-params (cdr (assoc :result-params params))))
|
|
(org-babel-result-cond result-params
|
|
result
|
|
(condition-case nil (org-babel-script-escape result)
|
|
(error result)))))))
|
|
|
|
(provide 'ob-clojure)
|
|
|
|
|
|
|
|
;;; ob-clojure.el ends here
|