e8cc7880c3
lisp/ * eieio/eieio-datadebug.el (data-debug/eieio-insert-slots): Inhibit read only while inserting objects. lisp/cedet/ * semantic.el (navigate-menu): Yank Tag :enable. Make sure `senator-tag-ring' is bound. (semantic-parse-region-default): Stop reversing the output of parse-whole-stream. (semantic-repeat-parse-whole-stream): Append returned tags differently, so they come out in the right order. * semantic/sb.el (semantic-sb-filter-tags-of-class): New option. (semantic-sb-fetch-tag-table): Filter tags being bucketed to exclude tags belonging to above filtered classes. * semantic/find.el (semantic-filter-tags-by-class): New function. * semantic/tag-ls.el (semantic-tag-similar-p-default): Add short-circuit in case tag1 and 2 are identical. * semantic/analyze/fcn.el (semantic-analyze-dereference-metatype-stack): Use `semantic-tag-similar-p' instead of 'eq' when comparing two tags during metatype evaluation in case they are the same, but not the same node. (Tweaked patch from Tomasz Gajewski) (Tiny change) * semantic/db-find.el (semanticdb-partial-synchronize): Fix require to semantic/db-typecache to be correct. (semanticdb-find-tags-external-children-of-type): Make this a brutish search by default. * semantic/sort.el (semantic-tag-external-member-children-default): When calling `semanticdb-find-tags-external-children-of-type', pass in the input tag as the place to start searching for externally defined methods. * semantic/db-file.el (semanticdb-default-save-directory): Doc fix: Add ref to default value. * semantic/complete.el (semantic-complete-post-command-hook): When detecting if cursor is outside completion area, do so if cursor moves before start of overlay, or the original starting location of the overlay (i.e., if user deletes past beginning of the overlay region). (semantic-complete-inline-tag-engine): Initialize original start of `semantic-complete-inline-overlay'. * semantic/bovine/c.el (semantic-c-describe-environment): Update some section titles. Test semanticdb table before printing it. (semantic-c-reset-preprocessor-symbol-map): Update `semantic-lex-spp-macro-symbol-obarray' outside the loop over all the files contributing to its value. (semantic-c-describe-environment): If there is an EDE project but no spp symbols from it, say so. * srecode/args.el (srecode-semantic-handle-:project): New argument handler. Provide variable values if not in an EDE project. * srecode/srt-mode.el (srecode-template-mode): Fix typo on srecode name. * srecode/cpp.el (srecode-semantic-handle-:c): Replace all characters in FILENAME_SYMBOL that aren't valid CPP symbol chars. * srecode/map.el (srecode-map-validate-file-for-mode): Force semantic to load if it is not active in the template being added to the map. * srecode/srt.el: Add local variables for setting the autoload file name. (srecode-semantic-handle-:srt): New autoload cookie * ede.el (ede-apply-preprocessor-map): Apply map to `semantic-lex-spp-project-macro-symbol-obarray' instead of the system one. Add require for semantic. * ede/proj-elisp.el (ede-update-version-in-source): In case a file has both a version variable and a Version: comment, always use `call-next-method'. * ede/cpp-root.el (ede-set-project-variables): Deleted. `ede-preprocessor-map' does the job this function was attempting to do with :spp-table. (ede-preprocessor-map): Update file tests to provide better messages. Do not try to get symbols from a file that is the file in the current buffer. * ede/base.el (ede-project-placeholder): Add more documentation to :file slot. (ede-load-cache): Use `insert-file-contents' instead of `find-file-noselect' in order to avoid activating other tools. * semantic/bovine/c.el (semantic-get-local-variables): Also add a new variable 'this' if we are in an inline member function. For detecting this, we check overlays at point if there is a class spanning the current function. Also, the variable 'this' has to be a pointer. * semantic/bovine/gcc.el (semantic-gcc-setup): Fail gracefully when querying g++ for defines returns an error. * srecode/srt-mode.el: * srecode/compile.el: * semantic/elp.el: * semantic/db-el.el: * semantic/complete.el: * ede.el: * cogre.el: * srecode/table.el: * srecode/mode.el: * srecode/insert.el: * srecode/compile.el: * semantic/decorate/include.el: * semantic/db.el: * semantic/adebug.el: * ede/auto.el: * srecode/dictionary.el: * semantic/ede-grammar.el: * semantic/db.el: * semantic/db-find.el: * semantic/db-file.el: * semantic/complete.el: * semantic/bovine/c.el: * semantic/analyze.el: * ede/util.el: * ede/proj.el: * ede/proj-elisp.el: * ede/pconf.el: * ede/locate.el: * ede.el: Adapt to EIEIO namespace cleanup: Rename `object-name' to `eieio-object-name', `object-set-name-string' to `eieio-object-set-name-string', `object-class' to `eieio-object-class', `class-parent' to `eieio-class-parent', `class-parents' to `eieio-class-parents', `class-children' to `eieio-class-children', `object-name-string' to `eieio-object-name-string', `object-class-fast' to `eieio--object-class'. Also replace direct access with new accessor functions. * ede/cpp-root.el (ede-project-autoload, initialize-instance): Fix EDE file symbol to match rename. Fix ede-cpp-root symbol to include -project in name. * cedet-files.el (cedet-files-list-recursively): New function. Recursively find files whose names are matching to given regex * ede.el (ede-current-project): Rewrite to avoid imperative style. * ede/files.el (ede-find-file): Simplify code. * ede/base.el (ede-normalize-file/directory): Add function to normalize :file or :directory slots if they are missing. * ede/cpp-root.el (ede-cpp-root-project): Add compile-command slot. (project-compile-project): Compiles project using value specified in :compule-command slot or in compile-command local variable. Value of slot or local variable could be string or function that receives project and should return string that will be invoked as command. (project-compile-target): Invokes compilation of whole project * ede/files.el (ede-find-project-root): New function to find root of project that contains specific file. (ede-files-find-existing): New function which checks presence of given directory in the list of registered projects. etc/ * srecode/ede-autoconf.srt: Change Copyright to FSF. (ede-empty): Change AC_INIT to use PROJECT_NAME, and PROJECT_VERSION. * srecode/ede-make.srt (ede-empty): Add a dependency on :project. Add header comment specifying the project's relative path. * srecode/c.srt (header_guard): Upcase the filename symbol. * srecode/java.srt (empty-main): New. (class-tag): Decapitalize class.
220 lines
8 KiB
EmacsLisp
220 lines
8 KiB
EmacsLisp
;;; semantic/ede-grammar.el --- EDE support for Semantic Grammar Files
|
|
|
|
;; Copyright (C) 2003-2004, 2007-2013 Free Software Foundation, Inc.
|
|
|
|
;; Author: Eric M. Ludlam <zappo@gnu.org>
|
|
;; Keywords: project, make
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <http://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
;;
|
|
;; Handle .by or .wy files.
|
|
|
|
(require 'semantic)
|
|
(require 'ede/proj)
|
|
(require 'ede/pmake)
|
|
(require 'ede/pconf)
|
|
(require 'ede/proj-elisp)
|
|
(require 'semantic/grammar)
|
|
|
|
;;; Code:
|
|
(defclass semantic-ede-proj-target-grammar (ede-proj-target-elisp)
|
|
((menu :initform nil)
|
|
(keybindings :initform nil)
|
|
(phony :initform t)
|
|
(sourcetype :initform
|
|
(semantic-ede-source-grammar-wisent
|
|
semantic-ede-source-grammar-bovine
|
|
))
|
|
(availablecompilers :initform
|
|
(semantic-ede-grammar-compiler-wisent
|
|
semantic-ede-grammar-compiler-bovine
|
|
))
|
|
(aux-packages :initform '("semantic" "cedet-compat"))
|
|
(pre-load-packages :initform '("cedet-compat" "semantic/grammar" "semantic/bovine/grammar" "semantic/wisent/grammar"))
|
|
)
|
|
"This target consists of a group of grammar files.
|
|
A grammar target consists of grammar files that build Emacs Lisp programs for
|
|
parsing different languages.")
|
|
|
|
(defmethod ede-proj-makefile-dependencies ((this semantic-ede-proj-target-grammar))
|
|
"Return a string representing the dependencies for THIS.
|
|
Some compilers only use the first element in the dependencies, others
|
|
have a list of intermediates (object files), and others don't care.
|
|
This allows customization of how these elements appear.
|
|
For Emacs Lisp, return addsuffix command on source files."
|
|
(let ((source (car (oref this source))))
|
|
(cond
|
|
((string-match "\\.wy$" source)
|
|
(format "$(addsuffix -wy.elc, $(basename $(%s)))"
|
|
(ede-proj-makefile-sourcevar this)))
|
|
((string-match "\\.by$" source)
|
|
(format "$(addsuffix -by.elc, $(basename $(%s)))"
|
|
(ede-proj-makefile-sourcevar this))))))
|
|
|
|
(defvar semantic-ede-source-grammar-wisent
|
|
(ede-sourcecode "semantic-ede-grammar-source-wisent"
|
|
:name "Wisent Grammar"
|
|
:sourcepattern "\\.wy$"
|
|
:garbagepattern '("*-wy.el")
|
|
)
|
|
"Semantic Grammar source code definition for wisent.")
|
|
|
|
(defclass semantic-ede-grammar-compiler-class (ede-compiler)
|
|
nil
|
|
"Specialized compiler for semantic grammars.")
|
|
|
|
(defvar semantic-ede-grammar-compiler-wisent
|
|
(semantic-ede-grammar-compiler-class
|
|
"ede-emacs-wisent-compiler"
|
|
:name "emacs"
|
|
:variables '(("EMACS" . "emacs")
|
|
("EMACSFLAGS" . "-batch --no-site-file --eval '(setq debug-on-error t)'")
|
|
("require" . "$(foreach r,$(1),(require (quote $(r))))"))
|
|
:rules (list (ede-makefile-rule
|
|
"elisp-inference-rule"
|
|
:target "%-wy.el"
|
|
:dependencies "%.wy"
|
|
:rules '("$(EMACS) $(EMACSFLAGS) $(addprefix -L ,$(LOADPATH)) \
|
|
--eval '(progn $(call require,$(PRELOADS)))' -f semantic-grammar-batch-build-packages $^")))
|
|
:sourcetype '(semantic-ede-source-grammar-wisent)
|
|
:objectextention "-wy.el"
|
|
)
|
|
"Compile Emacs Lisp programs.")
|
|
|
|
|
|
(defvar semantic-ede-source-grammar-bovine
|
|
(ede-sourcecode "semantic-ede-grammar-source-bovine"
|
|
:name "Bovine Grammar"
|
|
:sourcepattern "\\.by$"
|
|
:garbagepattern '("*-by.el")
|
|
)
|
|
"Semantic Grammar source code definition for the bovinator.")
|
|
|
|
(defvar semantic-ede-grammar-compiler-bovine
|
|
(semantic-ede-grammar-compiler-class
|
|
"ede-emacs-wisent-compiler"
|
|
:name "emacs"
|
|
:variables '(("EMACS" . "emacs")
|
|
("EMACSFLAGS" . "-batch --no-site-file --eval '(setq debug-on-error t)'")
|
|
("require" . "$(foreach r,$(1),(require (quote $(r))))"))
|
|
:rules (list (ede-makefile-rule
|
|
"elisp-inference-rule"
|
|
:target "%-by.el"
|
|
:dependencies "%.by"
|
|
:rules '("$(EMACS) $(EMACSFLAGS) $(addprefix -L ,$(LOADPATH)) \
|
|
--eval '(progn $(call require,$(PRELOADS)))' -f semantic-grammar-batch-build-packages $^")))
|
|
:sourcetype '(semantic-ede-source-grammar-bovine)
|
|
:objectextention "-by.el"
|
|
)
|
|
"Compile Emacs Lisp programs.")
|
|
|
|
;;; Target options.
|
|
(defmethod ede-buffer-mine ((this semantic-ede-proj-target-grammar) buffer)
|
|
"Return t if object THIS lays claim to the file in BUFFER.
|
|
Lays claim to all -by.el, and -wy.el files."
|
|
;; We need to be a little more careful than this, but at the moment it
|
|
;; is common to have only one target of this class per directory.
|
|
(if (string-match "-[bw]y\\.elc?$" (buffer-file-name buffer))
|
|
t
|
|
(call-next-method) ; The usual thing.
|
|
))
|
|
|
|
(defmethod project-compile-target ((obj semantic-ede-proj-target-grammar))
|
|
"Compile all sources in a Lisp target OBJ."
|
|
(let* ((cb (current-buffer))
|
|
(proj (ede-target-parent obj))
|
|
(default-directory (oref proj directory))
|
|
(comp 0)
|
|
(utd 0))
|
|
(mapc (lambda (src)
|
|
(with-current-buffer (find-file-noselect src)
|
|
(let* ((package (semantic-grammar-create-package))
|
|
(fname (progn (string-match ".*/\\(.+\\.el\\)" package)
|
|
(match-string 1 package)))
|
|
(src (with-current-buffer fname (buffer-file-name)))
|
|
(csrc (concat (file-name-sans-extension src) ".elc")))
|
|
(if (< emacs-major-version 24)
|
|
;; Does not have `byte-recompile-file'
|
|
(if (or (not (file-exists-p csrc))
|
|
(file-newer-than-file-p src csrc))
|
|
(progn
|
|
(setq comp (1+ comp))
|
|
(byte-compile-file src))
|
|
(setq utd (1+ utd)))
|
|
;; Emacs 24 and newer
|
|
(with-no-warnings
|
|
(if (eq (byte-recompile-file src nil 0) t)
|
|
(setq comp (1+ comp))
|
|
(setq utd (1+ utd))))))))
|
|
(oref obj source))
|
|
(message "All Semantic Grammar sources are up to date in %s" (eieio-object-name obj))
|
|
(cons comp utd)))
|
|
|
|
;;; Makefile generation functions
|
|
;;
|
|
(defmethod ede-proj-makefile-sourcevar ((this semantic-ede-proj-target-grammar))
|
|
"Return the variable name for THIS's sources."
|
|
(cond ((ede-proj-automake-p)
|
|
(error "No Automake support for Semantic Grammars"))
|
|
(t (concat (ede-pmake-varname this) "_SEMANTIC_GRAMMAR"))))
|
|
|
|
(defmethod ede-proj-makefile-insert-variables :AFTER ((this semantic-ede-proj-target-grammar))
|
|
"Insert variables needed by target THIS."
|
|
(ede-proj-makefile-insert-loadpath-items
|
|
(ede-proj-elisp-packages-to-loadpath
|
|
(list "eieio" "semantic" "inversion" "ede")))
|
|
;; eieio for object system needed in ede
|
|
;; semantic because it is
|
|
;; Inversion for versioning system.
|
|
;; ede for project regeneration
|
|
(ede-pmake-insert-variable-shared
|
|
(concat (ede-pmake-varname this) "_SEMANTIC_GRAMMAR_EL")
|
|
(insert
|
|
(mapconcat (lambda (src)
|
|
(with-current-buffer (find-file-noselect src)
|
|
(concat (semantic-grammar-package) ".el")))
|
|
(oref this source)
|
|
" ")))
|
|
)
|
|
|
|
(defmethod ede-proj-makefile-insert-rules :after ((this semantic-ede-proj-target-grammar))
|
|
"Insert rules needed by THIS target.
|
|
This raises `max-specpdl-size' and `max-lisp-eval-depth', which can be
|
|
needed for the compilation of the resulting parsers."
|
|
(insert (format "%s: EMACSFLAGS+= --eval '(setq max-specpdl-size 1500 \
|
|
max-lisp-eval-depth 700)'\n"
|
|
(oref this name))))
|
|
|
|
(defmethod ede-proj-makefile-insert-dist-dependencies ((this semantic-ede-proj-target-grammar))
|
|
"Insert dist dependencies, or intermediate targets.
|
|
This makes sure that all grammar lisp files are created before the dist
|
|
runs, so they are always up to date.
|
|
Argument THIS is the target that should insert stuff."
|
|
(call-next-method)
|
|
(insert " $(" (ede-pmake-varname this) "_SEMANTIC_GRAMMAR_EL)")
|
|
)
|
|
|
|
;; (autoload 'ede-proj-target-elisp "ede/proj-elisp"
|
|
;; "Target class for Emacs/Semantic grammar files." nil nil)
|
|
|
|
(ede-proj-register-target "semantic grammar"
|
|
semantic-ede-proj-target-grammar)
|
|
|
|
(provide 'semantic/ede-grammar)
|
|
|
|
;;; semantic/ede-grammar.el ends here
|