procyberian/emacs
1
0
Fork 0
Code Issues 1 Pull requests Projects 1 Releases Packages Wiki Activity Actions

New commands unix-word-rubout, unix-filename-rubout

Browse source 
* lisp/simple.el (forward-unix-word): New function.
(unix-word-rubout, unix-filename-rubout): New commands.
* etc/NEWS: Announce the new commands.
This commit is contained in:
Sean Whitton 2024-09-06 11:35:46 +01:00
parent 0a6e988b8d
commit f6417ba91b
2 changed files with 63 additions and 0 deletions
Show stats Download patch file Download diff file Expand all files Collapse all files

6
etc/NEWS
View file

@ -132,6 +132,12 @@ When using 'visual-wrap-prefix-mode' in buffers with variable-pitch
fonts, the wrapped text will now be lined up correctly so that it's
exactly below the text after the prefix on the first line.
---
** New commands 'unix-word-rubout' and 'unix-filename-rubout'.
Unix-words are words separated by whitespace regardless of the buffer's
syntax table. In a Unix terminal or shell, C-w kills by Unix-word.
The new commands 'unix-word-rubout' and 'unix-filename-rubout' allow
you to bind keys to operate more similarly to the terminal.
* Changes in Specialized Modes and Packages in Emacs 31.1

57
lisp/simple.el
View file

@ -8896,6 +8896,63 @@ constitute a word."
;; If we found something nonempty, return it as a string.
(unless (= start end)
(buffer-substring-no-properties start end)))))
(defun forward-unix-word (n &optional delim)
"Move forward N Unix-words.
A Unix-word is whitespace-delimited.
A negative N means go backwards to the beginning of Unix-words.
Unix-words differ from Emacs words in that they are always delimited by
whitespace, regardless of the buffer's syntax table. This function
emulates how C-w at the Unix terminal or shell identifies words.
Optional argument DELIM specifies what characters are considered
whitespace. It is a string as might be passed to `skip-chars-forward'.
The default is \"\\s\\f\\n\\r\\t\\v\". Do not prefix a `^' character."
(when (string-prefix-p "^" delim)
(error "DELIM argument must not begin with `^'"))
(unless (zerop n)
;; We do skip over newlines by default because `backward-word' does.
(let* ((delim (or delim "\s\f\n\r\t\v"))
(ndelim (format "^%s" delim))
(start (point))
(fun (if (> n 0)
#'skip-chars-forward
#'skip-chars-backward)))
(dotimes (_ (abs n))
(funcall fun delim)
(funcall fun ndelim))
(constrain-to-field nil start))))
(defun unix-word-rubout (arg)
"Kill ARG Unix-words backwards.
A Unix-word is whitespace-delimited.
Interactively, ARG is the numeric prefix argument, defaulting to 1.
A negative ARG means to kill forwards.
Unix-words differ from Emacs words in that they are always delimited by
whitespace, regardless of the buffer's syntax table.
Thus, this command emulates C-w at the Unix terminal or shell.
See also this command's nakesake in Info node
`(readline)Commands For Killing'."
(interactive "^p")
(let ((start (point)))
(forward-unix-word (- arg))
(kill-region start (point))))
(defun unix-filename-rubout (arg)
"Kill ARG Unix-words backwards, also treating slashes as word delimiters.
A Unix-word is whitespace-delimited.
Interactively, ARG is the numeric prefix argument, defaulting to 1.
A negative ARG means to kill forwards.
This is like `unix-word-rubout' (which see), but `/' and `\\' are also
treated as delimiting words. See this command's namesake in Info node
`(readline)Commands For Killing'."
(interactive "^p")
(let ((start (point)))
(forward-unix-word (- arg) "\\\\/\s\f\n\r\t\v")
(kill-region start (point))))
(defcustom fill-prefix nil
"String for filling to insert at front of new line, or nil for none."