mirror of
https://github.com/masscollaborationlabs/emacs.git
synced 2025-07-07 04:39:37 +00:00
ecf08f0621
dc4e6b1329; Update copyright years in more files64b3777631; Run set-copyright from admin.el8e1c56ae46; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
125 lines
4.7 KiB
EmacsLisp
125 lines
4.7 KiB
EmacsLisp
;;; find-func-tests.el --- Unit tests for find-func.el -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2020-2024 Free Software Foundation, Inc.
|
|
|
|
;; Author: Stefan Monnier <monnier@iro.umontreal.ca>
|
|
;; Keywords:
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;
|
|
|
|
;;; Code:
|
|
|
|
(require 'ert-x) ;For `ert-simulate-keys'.
|
|
(require 'find-func)
|
|
|
|
(ert-deftest find-func-tests--library-completion () ;bug#43393
|
|
;; FIXME: How can we make this work in batch (see also
|
|
;; `mule-cmds--test-universal-coding-system-argument')?
|
|
;; (skip-when noninteractive)
|
|
;; Check that `partial-completion' works when completing library names.
|
|
(should (equal "org/org"
|
|
(ert-simulate-keys
|
|
(kbd "o / o r g TAB RET")
|
|
(read-library-name))))
|
|
;; Check that absolute file names also work.
|
|
(should (equal (expand-file-name "nxml/" data-directory)
|
|
(ert-simulate-keys
|
|
(concat data-directory (kbd "n x / TAB RET"))
|
|
(read-library-name)))))
|
|
|
|
(ert-deftest find-func-tests--locate-symbols ()
|
|
(should (cdr
|
|
(find-function-search-for-symbol
|
|
#'goto-line nil "simple")))
|
|
(should (cdr
|
|
(find-function-search-for-symbol
|
|
'minibuffer-history 'defvar "simple")))
|
|
(should (cdr
|
|
(find-function-search-for-symbol
|
|
'with-current-buffer nil "subr")))
|
|
(should (cdr
|
|
(find-function-search-for-symbol
|
|
'font-lock-warning-face 'defface "font-lock")))
|
|
(should-not (cdr
|
|
(find-function-search-for-symbol
|
|
'wrong-variable 'defvar "simple")))
|
|
(should-not (cdr
|
|
(find-function-search-for-symbol
|
|
'wrong-function nil "simple")))
|
|
(should (cdr (find-function-noselect #'goto-line)))
|
|
(should (cdr (find-function-noselect #'goto-char)))
|
|
;; Setting LISP-ONLY and passing a primitive should error.
|
|
(should-error (find-function-noselect #'goto-char t))
|
|
(should-error (find-function-noselect 'wrong-function)))
|
|
|
|
(defun test-locate-helper (func &optional expected-result)
|
|
"Assert on the result of `find-function-library' for FUNC.
|
|
EXPECTED-RESULT is an alist (FUNC . LIBRARY) with the
|
|
expected function symbol and function library, respectively."
|
|
(cl-destructuring-bind (orig-function . library)
|
|
(find-function-library func)
|
|
(cl-destructuring-bind (expected-func . expected-library)
|
|
expected-result
|
|
(should (eq orig-function expected-func))
|
|
(should (and
|
|
(not (string-empty-p expected-library))
|
|
(string-match-p expected-library library))))))
|
|
|
|
(ert-deftest find-func-tests--locate-library ()
|
|
(test-locate-helper #'goto-line '(goto-line . "simple"))
|
|
(test-locate-helper #'forward-char '(forward-char . "cmds.c"))
|
|
(should-error (test-locate-helper 'wrong-function)))
|
|
|
|
(ert-deftest find-func-tests--locate-advised-symbols ()
|
|
(defun my-message ()
|
|
(message "Hello!"))
|
|
(advice-add #'mark-sexp :around 'my-message)
|
|
(test-locate-helper #'mark-sexp '(mark-sexp . "lisp"))
|
|
(advice-remove #'mark-sexp 'my-message))
|
|
|
|
(ert-deftest find-func-tests--find-library-verbose ()
|
|
(unwind-protect
|
|
(progn
|
|
(advice-add 'dired :before #'ignore)
|
|
;; bug#41104
|
|
(should (equal (find-function-library #'dired) '(dired . "dired"))))
|
|
(advice-remove 'dired #'ignore))
|
|
|
|
(find-function-library #'join-line nil t)
|
|
(with-current-buffer "*Messages*"
|
|
(save-excursion
|
|
(goto-char (point-max))
|
|
(skip-chars-backward "\n")
|
|
(should (string-match-p
|
|
".join-line. is an alias for .delete-indentation."
|
|
(buffer-substring (pos-bol) (point)))))))
|
|
|
|
;; Avoid a byte-compilation warning that may confuse people reading
|
|
;; the result of the following test.
|
|
(declare-function compilation--message->loc nil "compile")
|
|
|
|
(ert-deftest find-func-tests--locate-macro-generated-symbols () ;bug#45443
|
|
(should (cdr (find-function-search-for-symbol
|
|
#'compilation--message->loc nil "compile")))
|
|
(should (cdr (find-function-search-for-symbol
|
|
'c-mode-hook 'defvar "cc-mode"))))
|
|
|
|
(provide 'find-func-tests)
|
|
;;; find-func-tests.el ends here
|