mirror of
https://github.com/masscollaborationlabs/emacs.git
synced 2025-07-09 05:30:50 +00:00
ecf08f0621
dc4e6b1329; Update copyright years in more files64b3777631; Run set-copyright from admin.el8e1c56ae46; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
207 lines
8.6 KiB
EmacsLisp
207 lines
8.6 KiB
EmacsLisp
;;; multisession-tests.el --- Tests for multisession.el -*- lexical-binding: t; -*-
|
|
|
|
;; Copyright (C) 2021-2024 Free Software Foundation, Inc.
|
|
|
|
;; This file is part of GNU Emacs.
|
|
|
|
;; GNU Emacs is free software: you can redistribute it and/or modify
|
|
;; it under the terms of the GNU General Public License as published by
|
|
;; the Free Software Foundation, either version 3 of the License, or
|
|
;; (at your option) any later version.
|
|
|
|
;; GNU Emacs is distributed in the hope that it will be useful,
|
|
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
;; GNU General Public License for more details.
|
|
|
|
;; You should have received a copy of the GNU General Public License
|
|
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
|
|
|
;;; Commentary:
|
|
|
|
;;; Code:
|
|
|
|
(require 'multisession)
|
|
(require 'ert)
|
|
(require 'ert-x)
|
|
(require 'cl-lib)
|
|
|
|
(declare-function sqlite-close "sqlite.c")
|
|
|
|
(ert-deftest multi-test-sqlite-simple ()
|
|
(skip-unless (sqlite-available-p))
|
|
(ert-with-temp-file dir
|
|
:directory t
|
|
(let ((user-init-file "/tmp/foo.el")
|
|
(multisession-storage 'sqlite)
|
|
(multisession-directory dir))
|
|
(unwind-protect
|
|
(progn
|
|
(define-multisession-variable multisession--foo 0
|
|
""
|
|
:synchronized t)
|
|
(should (= (multisession-value multisession--foo) 0))
|
|
(cl-incf (multisession-value multisession--foo))
|
|
(should (= (multisession-value multisession--foo) 1))
|
|
(call-process
|
|
(concat invocation-directory invocation-name)
|
|
nil t nil
|
|
"-Q" "-batch"
|
|
"--eval" (prin1-to-string
|
|
`(progn
|
|
(require 'multisession)
|
|
(let ((multisession-directory ,dir)
|
|
(multisession-storage 'sqlite)
|
|
(user-init-file "/tmp/foo.el"))
|
|
(define-multisession-variable multisession--foo 0
|
|
""
|
|
:synchronized t)
|
|
(cl-incf (multisession-value multisession--foo))))))
|
|
(should (= (multisession-value multisession--foo) 2)))
|
|
(sqlite-close multisession--db)
|
|
(setq multisession--db nil)))))
|
|
|
|
(ert-deftest multi-test-sqlite-busy ()
|
|
(skip-unless (sqlite-available-p))
|
|
(ert-with-temp-file dir
|
|
:directory t
|
|
(let ((user-init-file "/tmp/foo.el")
|
|
(multisession-directory dir)
|
|
(multisession-storage 'sqlite)
|
|
proc)
|
|
(unwind-protect
|
|
(progn
|
|
(define-multisession-variable multisession--bar 0
|
|
""
|
|
:synchronized t)
|
|
(should (= (multisession-value multisession--bar) 0))
|
|
(cl-incf (multisession-value multisession--bar))
|
|
(should (= (multisession-value multisession--bar) 1))
|
|
(setq proc
|
|
(start-process
|
|
"other-emacs"
|
|
nil
|
|
(concat invocation-directory invocation-name)
|
|
"-Q" "-batch"
|
|
"--eval" (prin1-to-string
|
|
`(progn
|
|
(require 'multisession)
|
|
(let ((multisession-directory ,dir)
|
|
(multisession-storage 'sqlite)
|
|
(user-init-file "/tmp/bar.el"))
|
|
(define-multisession-variable multisession--bar 0
|
|
"" :synchronized t)
|
|
(dotimes (i 100)
|
|
(cl-incf (multisession-value multisession--bar))))))))
|
|
(while (process-live-p proc)
|
|
(ignore-error sqlite-locked-error
|
|
(message "multisession--bar %s" (multisession-value multisession--bar))
|
|
;;(cl-incf (multisession-value multisession--bar))
|
|
)
|
|
(sleep-for 0.1))
|
|
(message "multisession--bar ends up as %s" (multisession-value multisession--bar))
|
|
(should (< (multisession-value multisession--bar) 1003)))
|
|
(sqlite-close multisession--db)
|
|
(setq multisession--db nil)))))
|
|
|
|
(ert-deftest multi-test-files-simple ()
|
|
(ert-with-temp-file dir
|
|
:directory t
|
|
(let ((user-init-file "/tmp/sfoo.el")
|
|
(multisession-storage 'files)
|
|
(multisession-directory dir))
|
|
(define-multisession-variable multisession--sfoo 0
|
|
""
|
|
:synchronized t)
|
|
(should (= (multisession-value multisession--sfoo) 0))
|
|
(cl-incf (multisession-value multisession--sfoo))
|
|
(should (= (multisession-value multisession--sfoo) 1))
|
|
;; On Windows and Haiku, we don't have sub-second resolution, so
|
|
;; let some time pass to make the "later" logic work.
|
|
(when (memq system-type '(windows-nt haiku))
|
|
(sleep-for 0.6))
|
|
(call-process
|
|
(concat invocation-directory invocation-name)
|
|
nil t nil
|
|
"-Q" "-batch"
|
|
"--eval" (prin1-to-string
|
|
`(progn
|
|
(require 'multisession)
|
|
(let ((multisession-directory ,dir)
|
|
(multisession-storage 'files)
|
|
(user-init-file "/tmp/sfoo.el"))
|
|
(define-multisession-variable multisession--sfoo 0
|
|
""
|
|
:synchronized t)
|
|
(cl-incf (multisession-value multisession--sfoo))))))
|
|
(should (= (multisession-value multisession--sfoo) 2)))))
|
|
|
|
(ert-deftest multi-test-files-busy ()
|
|
(skip-unless (sqlite-available-p))
|
|
(ert-with-temp-file dir
|
|
:directory t
|
|
(let ((user-init-file "/tmp/foo.el")
|
|
(multisession-storage 'files)
|
|
(multisession-directory dir)
|
|
proc)
|
|
(define-multisession-variable multisession--sbar 0
|
|
""
|
|
:synchronized t)
|
|
(should (= (multisession-value multisession--sbar) 0))
|
|
(cl-incf (multisession-value multisession--sbar))
|
|
(should (= (multisession-value multisession--sbar) 1))
|
|
(setq proc
|
|
(start-process
|
|
"other-emacs"
|
|
nil
|
|
(concat invocation-directory invocation-name)
|
|
"-Q" "-batch"
|
|
"--eval" (prin1-to-string
|
|
`(progn
|
|
(require 'multisession)
|
|
(let ((multisession-directory ,dir)
|
|
(multisession-storage 'files)
|
|
(user-init-file "/tmp/sbar.el"))
|
|
(define-multisession-variable multisession--sbar 0
|
|
"" :synchronized t)
|
|
(dotimes (i 100)
|
|
(cl-incf (multisession-value multisession--sbar))))))))
|
|
(while (process-live-p proc)
|
|
(message "multisession--sbar %s" (multisession-value multisession--sbar))
|
|
;;(cl-incf (multisession-value multisession--sbar))
|
|
(sleep-for 0.1))
|
|
(message "multisession--sbar ends up as %s" (multisession-value multisession--sbar))
|
|
(should (< (multisession-value multisession--sbar) 200)))))
|
|
|
|
(ert-deftest multi-test-files-some-values ()
|
|
(ert-with-temp-file dir
|
|
:directory t
|
|
(let ((user-init-file "/tmp/sfoo.el")
|
|
(multisession-storage 'files)
|
|
(multisession-directory dir))
|
|
(define-multisession-variable multisession--foo1 nil)
|
|
(should (eq (multisession-value multisession--foo1) nil))
|
|
(setf (multisession-value multisession--foo1) nil)
|
|
(should (eq (multisession-value multisession--foo1) nil))
|
|
(setf (multisession-value multisession--foo1) t)
|
|
(should (eq (multisession-value multisession--foo1) t))
|
|
|
|
(define-multisession-variable multisession--foo2 t)
|
|
(setf (multisession-value multisession--foo2) nil)
|
|
(should (eq (multisession-value multisession--foo2) nil))
|
|
(setf (multisession-value multisession--foo2) t)
|
|
(should (eq (multisession-value multisession--foo2) t))
|
|
|
|
(define-multisession-variable multisession--foo3 t)
|
|
(should-error (setf (multisession-value multisession--foo3) (make-marker)))
|
|
|
|
(let ((string (with-temp-buffer
|
|
(set-buffer-multibyte nil)
|
|
(insert 0 1 2)
|
|
(buffer-string))))
|
|
(should-not (multibyte-string-p string))
|
|
(define-multisession-variable multisession--foo4 nil)
|
|
(setf (multisession-value multisession--foo4) string)
|
|
(should (equal (multisession-value multisession--foo4) string))))))
|
|
|
|
;;; multisession-tests.el ends here
|