mirror of
https://github.com/masscollaborationlabs/emacs.git
synced 2025-07-10 14:10:51 +00:00
ecf08f0621
dc4e6b1329; Update copyright years in more files64b3777631; Run set-copyright from admin.el8e1c56ae46; Add 2024 to copyright years # Conflicts: # doc/misc/modus-themes.org # doc/misc/texinfo.tex # etc/NEWS # etc/refcards/ru-refcard.tex # etc/themes/modus-operandi-theme.el # etc/themes/modus-themes.el # etc/themes/modus-vivendi-theme.el # lib/alloca.in.h # lib/binary-io.h # lib/c-ctype.h # lib/c-strcasecmp.c # lib/c-strncasecmp.c # lib/careadlinkat.c # lib/cloexec.c # lib/close-stream.c # lib/diffseq.h # lib/dup2.c # lib/filemode.h # lib/fpending.c # lib/fpending.h # lib/fsusage.c # lib/getgroups.c # lib/getloadavg.c # lib/gettext.h # lib/gettime.c # lib/gettimeofday.c # lib/group-member.c # lib/malloc.c # lib/md5-stream.c # lib/md5.c # lib/md5.h # lib/memmem.c # lib/memrchr.c # lib/nanosleep.c # lib/save-cwd.h # lib/sha1.c # lib/sig2str.c # lib/stdlib.in.h # lib/strtoimax.c # lib/strtol.c # lib/strtoll.c # lib/time_r.c # lib/xalloc-oversized.h # lisp/auth-source-pass.el # lisp/emacs-lisp/lisp-mnt.el # lisp/emacs-lisp/timer.el # lisp/info-look.el # lisp/jit-lock.el # lisp/loadhist.el # lisp/mail/rmail.el # lisp/net/ntlm.el # lisp/net/webjump.el # lisp/progmodes/asm-mode.el # lisp/progmodes/project.el # lisp/progmodes/sh-script.el # lisp/textmodes/flyspell.el # lisp/textmodes/reftex-toc.el # lisp/textmodes/reftex.el # lisp/textmodes/tex-mode.el # lisp/url/url-gw.el # m4/alloca.m4 # m4/clock_time.m4 # m4/d-type.m4 # m4/dirent_h.m4 # m4/dup2.m4 # m4/euidaccess.m4 # m4/fchmodat.m4 # m4/filemode.m4 # m4/fsusage.m4 # m4/getgroups.m4 # m4/getloadavg.m4 # m4/getrandom.m4 # m4/gettime.m4 # m4/gettimeofday.m4 # m4/gnulib-common.m4 # m4/group-member.m4 # m4/inttypes.m4 # m4/malloc.m4 # m4/manywarnings.m4 # m4/mempcpy.m4 # m4/memrchr.m4 # m4/mkostemp.m4 # m4/mktime.m4 # m4/nproc.m4 # m4/nstrftime.m4 # m4/pathmax.m4 # m4/pipe2.m4 # m4/pselect.m4 # m4/pthread_sigmask.m4 # m4/readlink.m4 # m4/realloc.m4 # m4/sig2str.m4 # m4/ssize_t.m4 # m4/stat-time.m4 # m4/stddef_h.m4 # m4/stdint.m4 # m4/stdio_h.m4 # m4/stdlib_h.m4 # m4/stpcpy.m4 # m4/strnlen.m4 # m4/strtoimax.m4 # m4/strtoll.m4 # m4/time_h.m4 # m4/timegm.m4 # m4/timer_time.m4 # m4/timespec.m4 # m4/unistd_h.m4 # m4/warnings.m4 # nt/configure.bat # nt/preprep.c # test/lisp/register-tests.el
138 lines
5.1 KiB
EmacsLisp
138 lines
5.1 KiB
EmacsLisp
;;; cus-edit-tests.el --- Tests for cus-edit.el -*- lexical-binding: t -*-
|
||
|
||
;; Copyright (C) 2020-2024 Free Software Foundation, Inc.
|
||
|
||
;; This file is part of GNU Emacs.
|
||
|
||
;; GNU Emacs is free software: you can redistribute it and/or modify
|
||
;; it under the terms of the GNU General Public License as published by
|
||
;; the Free Software Foundation, either version 3 of the License, or
|
||
;; (at your option) any later version.
|
||
|
||
;; GNU Emacs is distributed in the hope that it will be useful,
|
||
;; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
||
;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
||
;; GNU General Public License for more details.
|
||
|
||
;; You should have received a copy of the GNU General Public License
|
||
;; along with GNU Emacs. If not, see <https://www.gnu.org/licenses/>.
|
||
|
||
;;; Commentary:
|
||
|
||
;;; Code:
|
||
|
||
(require 'ert)
|
||
(require 'ert-x)
|
||
(eval-when-compile (require 'cl-lib))
|
||
(require 'cus-edit)
|
||
|
||
(defmacro with-cus-edit-test (buffer &rest body)
|
||
(declare (indent 1))
|
||
`(save-window-excursion
|
||
(unwind-protect
|
||
(progn ,@body)
|
||
(when-let ((buf (get-buffer ,buffer)))
|
||
(kill-buffer buf)))))
|
||
|
||
|
||
;;;; showing/hiding obsolete options
|
||
|
||
(defgroup cus-edit-tests nil "Test."
|
||
:group 'test-group)
|
||
|
||
(defcustom cus-edit-tests--obsolete-option-tag nil
|
||
"This should never be removed; it is obsolete for testing purposes."
|
||
:type 'boolean
|
||
:version "917.10") ; a super high version number
|
||
(make-obsolete-variable 'cus-edit-tests--obsolete-option-tag nil "X.X-test")
|
||
(defconst cus-edit-tests--obsolete-option-tag
|
||
(custom-unlispify-tag-name 'cus-edit-tests--obsolete-option-tag))
|
||
|
||
(ert-deftest cus-edit-tests-customize-apropos/hide-obsolete ()
|
||
(with-cus-edit-test "*Customize Apropos*"
|
||
(customize-apropos "cus-edit-tests")
|
||
(should-not (search-forward cus-edit-tests--obsolete-option-tag nil t))))
|
||
|
||
(ert-deftest cus-edit-tests-customize-changed/hide-obsolete ()
|
||
(with-cus-edit-test "*Customize Changed Options*"
|
||
(customize-changed "917.2") ;; Some future version.
|
||
(should-not (search-forward cus-edit-tests--obsolete-option-tag nil t))))
|
||
|
||
(ert-deftest cus-edit-tests-customize-group/hide-obsolete ()
|
||
"Check that obsolete variables do not show up."
|
||
(with-cus-edit-test "*Customize Group: Cus Edit Tests*"
|
||
(customize-group 'cus-edit-tests)
|
||
(should-not (search-forward cus-edit-tests--obsolete-option-tag nil t))))
|
||
|
||
(ert-deftest cus-edit-tests-customize-option/show-obsolete ()
|
||
(with-cus-edit-test "*Customize Option: Cus Edit Tests Obsolete Option Tag*"
|
||
(customize-option 'cus-edit-tests--obsolete-option-tag)
|
||
(goto-char (point-min))
|
||
(should (search-forward cus-edit-tests--obsolete-option-tag nil t))))
|
||
|
||
(ert-deftest cus-edit-tests-customize-saved/show-obsolete ()
|
||
(with-cus-edit-test "*Customize Saved*"
|
||
(cl-letf (((get 'cus-edit-tests--obsolete-option-tag 'saved-value) '(t)))
|
||
(customize-saved)
|
||
(should (search-forward cus-edit-tests--obsolete-option-tag nil t)))))
|
||
|
||
(defcustom cus-edit-test-foo1 0
|
||
""
|
||
:type 'number)
|
||
|
||
(ert-deftest test-setopt ()
|
||
(should (= (setopt cus-edit-test-foo1 1) 1))
|
||
(should (= cus-edit-test-foo1 1))
|
||
(let* ((text-quoting-style 'grave)
|
||
(warn-txt
|
||
(with-current-buffer (get-buffer-create "*Warnings*")
|
||
(let ((inhibit-read-only t))
|
||
(erase-buffer))
|
||
(setopt cus-edit-test-foo1 :foo)
|
||
(buffer-substring-no-properties (point-min) (point-max)))))
|
||
(should (string-search "Value `:foo' does not match type number"
|
||
warn-txt))))
|
||
|
||
(defcustom cus-edit-test-bug63290-option nil
|
||
"Choice option for testing Bug#63290."
|
||
:type '(choice (alist
|
||
:key-type (string :tag "key")
|
||
:value-type (string :tag "value"))
|
||
(const :tag "auto" auto)))
|
||
|
||
(defcustom cus-edit-test-bug63290-option2 'some
|
||
"Choice option for testing Bug#63290."
|
||
:type '(choice
|
||
(const :tag "some" some)
|
||
(alist
|
||
:key-type (string :tag "key")
|
||
:value-type (string :tag "value"))))
|
||
|
||
(ert-deftest cus-edit-test-bug63290 ()
|
||
"Test that changing a choice value back to an alist respects its nil value."
|
||
(customize-variable 'cus-edit-test-bug63290-option)
|
||
(search-forward "Value")
|
||
;; Simulate changing the value.
|
||
(let* ((choice (widget-at))
|
||
(args (widget-get choice :args))
|
||
(list-opt (car (widget-get choice :children)))
|
||
(const-opt (nth 1 args)))
|
||
(widget-put choice :explicit-choice const-opt)
|
||
(widget-value-set choice (widget-default-get const-opt))
|
||
(widget-put choice :explicit-choice list-opt)
|
||
(widget-value-set choice (widget-default-get list-opt)))
|
||
;; No empty key/value pairs should show up.
|
||
(should-not (search-forward "key" nil t))
|
||
(customize-variable 'cus-edit-test-bug63290-option2)
|
||
(search-forward "Value")
|
||
;; Simulate changing the value.
|
||
(let* ((choice (widget-at))
|
||
(args (widget-get choice :args))
|
||
(list-opt (nth 1 args)))
|
||
(widget-put choice :explicit-choice list-opt)
|
||
(widget-value-set choice (widget-default-get list-opt)))
|
||
;; No empty key/value pairs should show up.
|
||
(should-not (search-forward "key" nil t)))
|
||
|
||
(provide 'cus-edit-tests)
|
||
;;; cus-edit-tests.el ends here
|